cd2ede593a
1401fb85 Fix `a label can only be part of a statement` warning (#61) 5f650a18 CMake: Enable `CMAKE_MSVC_RUNTIME_LIBRARY` (MSVC) 6c958cfe Fix no-libc build on "other" platforms (#58) 59819206 Bump version to v1.4.0 4bc563f6 Fix build-system to better work with vcpkg (#56) 4a8b5e2a CMake: rename target `doc` -> `ZycoreDoc` a754e112 Bump version to 1.3.0 3e95307d Add support for ppc(64) and riscv64 (#52) 8f39333a build: only enable CXX if needed 7bd75696 build: add doc target 7c33e13e Fix `ZYAN_TRUE`/`ZYAN_FALSE` signedness a0feec7f Fix warning `C4668` bdbd3ff4 Bump version to v1.2 60b6ef1c Fix for dynamic libraries too 310f362c Adding ARCHIVE DESTINATION to fix CMake error b01063b8 Improved logic for enabling LTO c58d7fb5 Don't enable C11 for MSVC ee784564 Switch minimum C standard supported to C11 5c341bf1 Implement an initial set of cross-compiler atomic operations b4949ccc Minor fixes 9a305f6a Add CI workflow dd2211a0 Get rid of CMake export headers f0fb3f78 Fix `ZYAN_VECTOR_FOREACH_MUTABLE` macro 3f263290 format: handle encoding on wasm 95d7fb6c format: handle hex encoding on wasm 0d37fc54 defines: add wasm/wasi detection 8983325b build: use -pthread when possible 3de49d41 build: use system GTest when available 8d46cb58 test: make tests runnable with ctest 636bb299 Remove `float`s from the project (kernel mode compatibility) (#36) e2b37b10 Assert to ensure sane growth factors 94185407 Added limits for integer types 767719d9 build(cmake): export and install zyan_* functions (#33) 6c93d9a3 build(cmake): add version and soversion to the library fc2798d4 build(cmake): fix PUBLIC include dir of installed lib 22ce9c2d Add `ZYAN_FORCE_ASSERTS` CMake option 9a301424 Remove disabling source files in no-libc mode in CMake 3be54fca Thread.c: add missing SDK prototypes for old versions of Windows d7fc85fd Exclude API/Memory.c and API/Process.c from compilation in no-libc mode 8da0001a Add back #ifdef guards to "API" headers/sources for no-libc mode f6a48866 Fix cmake config files (#27) 4f3746fa Merge pull request #26 from Tsn0w/master a9bb54ad Replace fallthrough attribute to __fallthrough__ 99a74acb Add `ZYDIS_NOINLINE` macro git-subtree-dir: externals/zycore git-subtree-split: 1401fb85ac313f6605ec795c52bf99ea3f292a69
201 lines
6.7 KiB
CMake
201 lines
6.7 KiB
CMake
cmake_minimum_required(VERSION 3.12)
|
|
project(dynarmic LANGUAGES C CXX ASM VERSION 6.3.0)
|
|
|
|
# Determine if we're built as a subproject (using add_subdirectory)
|
|
# or if this is the master project.
|
|
set(MASTER_PROJECT OFF)
|
|
if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
|
|
set(MASTER_PROJECT ON)
|
|
endif()
|
|
|
|
# Dynarmic project options
|
|
option(DYNARMIC_ENABLE_CPU_FEATURE_DETECTION "Turning this off causes dynarmic to assume the host CPU doesn't support anything later than SSE3" ON)
|
|
option(DYNARMIC_ENABLE_NO_EXECUTE_SUPPORT "Enables support for systems that require W^X" OFF)
|
|
option(DYNARMIC_FATAL_ERRORS "Errors are fatal" OFF)
|
|
option(DYNARMIC_IGNORE_ASSERTS "Ignore asserts" OFF)
|
|
option(DYNARMIC_TESTS "Build tests" ${MASTER_PROJECT})
|
|
option(DYNARMIC_TESTS_USE_UNICORN "Enable fuzzing tests against unicorn" OFF)
|
|
option(DYNARMIC_USE_LLVM "Support disassembly of jitted x86_64 code using LLVM" OFF)
|
|
option(DYNARMIC_WARNINGS_AS_ERRORS "Warnings as errors" ${MASTER_PROJECT})
|
|
if (NOT DEFINED DYNARMIC_FRONTENDS)
|
|
set(DYNARMIC_FRONTENDS "A32;A64" CACHE STRING "Selects which frontends to enable")
|
|
endif()
|
|
|
|
# Default to a Release build
|
|
if (NOT CMAKE_BUILD_TYPE)
|
|
set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
|
|
message(STATUS "Defaulting to a Release build")
|
|
endif()
|
|
|
|
# Set hard requirements for C++
|
|
set(CMAKE_CXX_STANDARD 20)
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
|
|
# Disable in-source builds
|
|
set(CMAKE_DISABLE_SOURCE_CHANGES ON)
|
|
set(CMAKE_DISABLE_IN_SOURCE_BUILD ON)
|
|
if ("${CMAKE_SOURCE_DIR}" STREQUAL "${CMAKE_BINARY_DIR}")
|
|
message(SEND_ERROR "In-source builds are not allowed.")
|
|
endif()
|
|
|
|
# Add the module directory to the list of paths
|
|
list(APPEND CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules")
|
|
|
|
# Compiler flags
|
|
if (MSVC)
|
|
set(DYNARMIC_CXX_FLAGS
|
|
/experimental:external
|
|
/external:W0
|
|
/external:anglebrackets
|
|
/W4
|
|
/w44263 # Non-virtual member function hides base class virtual function
|
|
/w44265 # Class has virtual functions, but destructor is not virtual
|
|
/w44456 # Declaration of 'var' hides previous local declaration
|
|
/w44457 # Declaration of 'var' hides function parameter
|
|
/w44458 # Declaration of 'var' hides class member
|
|
/w44459 # Declaration of 'var' hides global definition
|
|
/w44946 # Reinterpret-cast between related types
|
|
/wd4592 # Symbol will be dynamically initialized (implementation limitation)
|
|
/permissive- # Stricter C++ standards conformance
|
|
/MP
|
|
/Zi
|
|
/Zo
|
|
/EHsc
|
|
/Zc:externConstexpr # Allows external linkage for variables declared "extern constexpr", as the standard permits.
|
|
/Zc:inline # Omits inline functions from object-file output.
|
|
/Zc:throwingNew # Assumes new (without std::nothrow) never returns null.
|
|
/volatile:iso # Use strict standard-abiding volatile semantics
|
|
/bigobj # Increase number of sections in .obj files
|
|
/DNOMINMAX)
|
|
|
|
if (DYNARMIC_WARNINGS_AS_ERRORS)
|
|
list(APPEND DYNARMIC_CXX_FLAGS
|
|
/WX)
|
|
endif()
|
|
|
|
if (CMAKE_VS_PLATFORM_TOOLSET MATCHES "LLVM-vs[0-9]+")
|
|
list(APPEND DYNARMIC_CXX_FLAGS
|
|
-Qunused-arguments
|
|
-Wno-missing-braces)
|
|
endif()
|
|
else()
|
|
set(DYNARMIC_CXX_FLAGS
|
|
-Wall
|
|
-Wextra
|
|
-Wcast-qual
|
|
-pedantic
|
|
-pedantic-errors
|
|
-Wno-missing-braces)
|
|
|
|
if (DYNARMIC_WARNINGS_AS_ERRORS)
|
|
list(APPEND DYNARMIC_CXX_FLAGS
|
|
-Werror)
|
|
endif()
|
|
|
|
if (DYNARMIC_FATAL_ERRORS)
|
|
list(APPEND DYNARMIC_CXX_FLAGS
|
|
-Wfatal-errors)
|
|
endif()
|
|
|
|
if (CMAKE_CXX_COMPILER_ID MATCHES "[Cc]lang")
|
|
# Bracket depth determines maximum size of a fold expression in Clang since 9c9974c3ccb6.
|
|
# And this in turns limits the size of a std::array.
|
|
list(APPEND DYNARMIC_CXX_FLAGS -fbracket-depth=1024)
|
|
endif()
|
|
endif()
|
|
|
|
# Arch detection
|
|
include(DetectArchitecture)
|
|
if (NOT DEFINED ARCHITECTURE)
|
|
message(FATAL_ERROR "Unsupported architecture encountered. Ending CMake generation.")
|
|
endif()
|
|
message(STATUS "Target architecture: ${ARCHITECTURE}")
|
|
|
|
# Include Boost
|
|
if (NOT TARGET boost)
|
|
if (NOT Boost_INCLUDE_DIRS)
|
|
find_package(Boost 1.57.0 REQUIRED)
|
|
endif()
|
|
add_library(boost INTERFACE)
|
|
target_include_directories(boost SYSTEM INTERFACE ${Boost_INCLUDE_DIRS})
|
|
endif()
|
|
|
|
if (DYNARMIC_NO_BUNDLED_FMT AND NOT TARGET fmt AND NOT TARGET fmt::fmt)
|
|
find_package(fmt REQUIRED)
|
|
add_library(fmt ALIAS fmt::fmt)
|
|
endif()
|
|
|
|
if (DYNARMIC_NO_BUNDLED_ROBIN_MAP AND NOT TARGET tsl::robin_map)
|
|
find_package(tsl-robin-map REQUIRED)
|
|
endif()
|
|
|
|
if (DYNARMIC_NO_BUNDLED_XBYAK AND NOT TARGET xbyak)
|
|
if (ARCHITECTURE STREQUAL "x86" OR ARCHITECTURE STREQUAL "x86_64")
|
|
find_package(xbyak REQUIRED)
|
|
add_library(xbyak ALIAS xbyak::xbyak)
|
|
endif()
|
|
endif()
|
|
|
|
if (DYNARMIC_NO_BUNDLED_ZYDIS AND NOT TARGET Zydis)
|
|
find_package(Zydis REQUIRED)
|
|
add_library(Zydis ALIAS Zydis::Zydis)
|
|
endif()
|
|
|
|
# Enable unit-testing.
|
|
enable_testing(true)
|
|
|
|
# Include LLVM
|
|
if (DYNARMIC_USE_LLVM)
|
|
find_package(LLVM REQUIRED CONFIG)
|
|
include_directories(${LLVM_INCLUDE_DIRS})
|
|
add_definitions(-DDYNARMIC_USE_LLVM ${LLVM_DEFINITIONS})
|
|
llvm_map_components_to_libnames(llvm_libs armdesc armdisassembler aarch64desc aarch64disassembler x86desc x86disassembler)
|
|
endif()
|
|
|
|
if (DYNARMIC_TESTS_USE_UNICORN AND DYNARMIC_TESTS)
|
|
find_package(Unicorn REQUIRED)
|
|
endif()
|
|
|
|
if (DYNARMIC_TESTS AND DYNARMIC_NO_BUNDLED_CATCH AND NOT TARGET catch)
|
|
find_package(Catch2 REQUIRED)
|
|
add_library(catch ALIAS Catch2::Catch2)
|
|
endif()
|
|
|
|
# Pull in externals CMakeLists for libs where available
|
|
add_subdirectory(externals)
|
|
|
|
# Dynarmic project files
|
|
add_subdirectory(src/dynarmic)
|
|
if (DYNARMIC_TESTS)
|
|
add_subdirectory(tests)
|
|
endif()
|
|
|
|
#
|
|
# Install
|
|
#
|
|
if (MASTER_PROJECT)
|
|
include(GNUInstallDirs)
|
|
include(CMakePackageConfigHelpers)
|
|
|
|
install(TARGETS dynarmic EXPORT dynarmicTargets)
|
|
install(EXPORT dynarmicTargets
|
|
NAMESPACE dynarmic::
|
|
DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/dynarmic"
|
|
)
|
|
|
|
configure_package_config_file(CMakeModules/dynarmicConfig.cmake.in
|
|
dynarmicConfig.cmake
|
|
INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/dynarmic"
|
|
)
|
|
write_basic_package_version_file(dynarmicConfigVersion.cmake
|
|
COMPATIBILITY SameMajorVersion
|
|
)
|
|
install(FILES
|
|
"${CMAKE_CURRENT_BINARY_DIR}/dynarmicConfig.cmake"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/dynarmicConfigVersion.cmake"
|
|
DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/dynarmic"
|
|
)
|
|
|
|
install(DIRECTORY src/dynarmic TYPE INCLUDE FILES_MATCHING PATTERN "*.h")
|
|
endif()
|