43a28c2083
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/prosody/versions. These checks were done: - built on NixOS - /nix/store/9vcfnh0ghw9qmljbmpb52l5xwq8b8k4i-prosody-0.10.1/bin/prosody passed the binary check. - Warning: no invocation of /nix/store/9vcfnh0ghw9qmljbmpb52l5xwq8b8k4i-prosody-0.10.1/bin/prosodyctl had a zero exit code or showed the expected version - /nix/store/9vcfnh0ghw9qmljbmpb52l5xwq8b8k4i-prosody-0.10.1/bin/.prosody-wrapped passed the binary check. - Warning: no invocation of /nix/store/9vcfnh0ghw9qmljbmpb52l5xwq8b8k4i-prosody-0.10.1/bin/.prosodyctl-wrapped had a zero exit code or showed the expected version - 2 of 4 passed binary check by having a zero exit code. - 0 of 4 passed binary check by having the new version present in output. - found 0.10.1 with grep in /nix/store/9vcfnh0ghw9qmljbmpb52l5xwq8b8k4i-prosody-0.10.1 - directory tree listing: https://gist.github.com/e1e8caae1a498d8e07f1c35d990846d3 - du listing: https://gist.github.com/9b3a9c7a8711da781e548e894e848cdc
73 lines
2.4 KiB
Nix
73 lines
2.4 KiB
Nix
{ stdenv, fetchurl, libidn, openssl, makeWrapper, fetchhg
|
|
, lua5, luasocket, luasec, luaexpat, luafilesystem, luabitop
|
|
, withLibevent ? true, luaevent ? null
|
|
, withDBI ? true, luadbi ? null
|
|
# use withExtraLibs to add additional dependencies of community modules
|
|
, withExtraLibs ? [ ]
|
|
, withOnlyInstalledCommunityModules ? [ ]
|
|
, withCommunityModules ? [ ] }:
|
|
|
|
assert withLibevent -> luaevent != null;
|
|
assert withDBI -> luadbi != null;
|
|
|
|
with stdenv.lib;
|
|
|
|
let
|
|
libs = [ luasocket luasec luaexpat luafilesystem luabitop ]
|
|
++ optional withLibevent luaevent
|
|
++ optional withDBI luadbi
|
|
++ withExtraLibs;
|
|
getPath = lib : type : "${lib}/lib/lua/${lua5.luaversion}/?.${type};${lib}/share/lua/${lua5.luaversion}/?.${type}";
|
|
getLuaPath = lib : getPath lib "lua";
|
|
getLuaCPath = lib : getPath lib "so";
|
|
luaPath = concatStringsSep ";" (map getLuaPath libs);
|
|
luaCPath = concatStringsSep ";" (map getLuaCPath libs);
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "0.10.1";
|
|
name = "prosody-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://prosody.im/downloads/source/${name}.tar.gz";
|
|
sha256 = "1kmmpkkgymg1r8r0k8j83pgmiskg1phl8hmpzjrnvlvsfnrnjplr";
|
|
};
|
|
|
|
communityModules = fetchhg {
|
|
url = "https://hg.prosody.im/prosody-modules";
|
|
rev = "150a7bd59043";
|
|
sha256 = "0nfx3lngcy88nd81gb7v4kh3nz1bzsm67bxgpd2lprk54diqcrz1";
|
|
};
|
|
|
|
buildInputs = [ lua5 makeWrapper libidn openssl ]
|
|
++ optional withDBI luadbi;
|
|
|
|
configureFlags = [
|
|
"--ostype=linux"
|
|
"--with-lua-include=${lua5}/include"
|
|
"--with-lua=${lua5}"
|
|
];
|
|
|
|
postInstall = ''
|
|
${concatMapStringsSep "\n" (module: ''
|
|
cp -r $communityModules/mod_${module} $out/lib/prosody/modules/
|
|
'') (withCommunityModules ++ withOnlyInstalledCommunityModules)}
|
|
wrapProgram $out/bin/prosody \
|
|
--set LUA_PATH '${luaPath};' \
|
|
--set LUA_CPATH '${luaCPath};'
|
|
wrapProgram $out/bin/prosodyctl \
|
|
--add-flags '--config "/etc/prosody/prosody.cfg.lua"' \
|
|
--set LUA_PATH '${luaPath};' \
|
|
--set LUA_CPATH '${luaCPath};'
|
|
'';
|
|
|
|
passthru.communityModules = withCommunityModules;
|
|
|
|
meta = {
|
|
description = "Open-source XMPP application server written in Lua";
|
|
license = licenses.mit;
|
|
homepage = https://prosody.im;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ fpletz globin ];
|
|
};
|
|
}
|