fbb86b1fa8
* remove glibcLocales now that glibc contains C.UTF-8 * remove libintl, that should be in by default or something * update homepage * add gnome team to maintainers * remove the temporary libregress closer its creation
119 lines
3.1 KiB
Nix
119 lines
3.1 KiB
Nix
{ stdenv
|
|
, fetchurl
|
|
, glib
|
|
, flex
|
|
, bison
|
|
, meson
|
|
, ninja
|
|
, pkg-config
|
|
, libffi
|
|
, python3
|
|
, cctools
|
|
, cairo
|
|
, gnome3
|
|
, substituteAll
|
|
, nixStoreDir ? builtins.storeDir
|
|
, x11Support ? true
|
|
}:
|
|
|
|
# now that gobject-introspection creates large .gir files (eg gtk3 case)
|
|
# it may be worth thinking about using multiple derivation outputs
|
|
# In that case its about 6MB which could be separated
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "gobject-introspection";
|
|
version = "1.64.1";
|
|
|
|
# outputs TODO: share/gobject-introspection-1.0/tests is needed during build
|
|
# by pygobject3 (and maybe others), but it's only searched in $out
|
|
outputs = [ "out" "dev" "man" ];
|
|
outputBin = "dev";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnome/sources/${pname}/${stdenv.lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
|
|
sha256 = "19vz7vp10h0zj3f491yk72dp89bix6rgkzxg4qcm4d6151ksxgl0";
|
|
};
|
|
|
|
patches = [
|
|
(substituteAll {
|
|
src = ./test_shlibs.patch;
|
|
inherit nixStoreDir;
|
|
})
|
|
|
|
(substituteAll {
|
|
src = ./absolute_shlib_path.patch;
|
|
inherit nixStoreDir;
|
|
})
|
|
] ++ stdenv.lib.optionals x11Support [
|
|
# https://github.com/NixOS/nixpkgs/issues/34080
|
|
(substituteAll {
|
|
src = ./absolute_gir_path.patch;
|
|
cairoLib = "${stdenv.lib.getLib cairo}/lib";
|
|
})
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = [
|
|
flex
|
|
bison
|
|
python3
|
|
setupHook /*move .gir*/
|
|
] ++ stdenv.lib.optionals stdenv.isDarwin [
|
|
cctools
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
libffi
|
|
glib
|
|
];
|
|
|
|
mesonFlags = [
|
|
"--datadir=${placeholder "dev"}/share"
|
|
"-Ddoctool=disabled"
|
|
"-Dcairo=disabled"
|
|
];
|
|
|
|
doCheck = !stdenv.isAarch64;
|
|
|
|
preCheck = ''
|
|
# Our gobject-introspection patches make the shared library paths absolute
|
|
# in the GIR files. When running tests, the library is not yet installed,
|
|
# though, so we need to replace the absolute path with a local one during build.
|
|
# We are using a symlink that we will delete before installation.
|
|
mkdir -p $out/lib
|
|
ln -s $PWD/tests/scanner/libregress-1.0${stdenv.targetPlatform.extensions.sharedLibrary} $out/lib/libregress-1.0${stdenv.targetPlatform.extensions.sharedLibrary}
|
|
'';
|
|
|
|
postCheck = ''
|
|
rm $out/lib/libregress-1.0${stdenv.targetPlatform.extensions.sharedLibrary}
|
|
'';
|
|
|
|
setupHook = ./setup-hook.sh;
|
|
|
|
passthru = {
|
|
updateScript = gnome3.updateScript {
|
|
packageName = pname;
|
|
};
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A middleware layer between C libraries and language bindings";
|
|
homepage = "https://gi.readthedocs.io/";
|
|
maintainers = teams.gnome.members ++ (with maintainers; [ lovek323 ]);
|
|
platforms = platforms.unix;
|
|
license = with licenses; [ gpl2 lgpl2 ];
|
|
|
|
longDescription = ''
|
|
GObject introspection is a middleware layer between C libraries (using
|
|
GObject) and language bindings. The C library can be scanned at compile
|
|
time and generate a metadata file, in addition to the actual native C
|
|
library. Then at runtime, language bindings can read this metadata and
|
|
automatically provide bindings to call into the C library.
|
|
'';
|
|
};
|
|
}
|