46420bbaa3
treewide replacement of
stdenv.mkDerivation rec {
name = "*-${version}";
version = "*";
to pname
49 lines
1.4 KiB
Nix
49 lines
1.4 KiB
Nix
{ stdenv, fetchFromGitHub, meson, pkgconfig, ninja, docutils
|
|
, fuse3, glib
|
|
, which, python3Packages
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "3.5.2";
|
|
pname = "sshfs-fuse";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "libfuse";
|
|
repo = "sshfs";
|
|
rev = "sshfs-${version}";
|
|
sha256 = "0gvk8snivpi2sjidjnd9ypc66ny7lr0z9v4swl56rwjv539dkbx2";
|
|
};
|
|
|
|
nativeBuildInputs = [ meson pkgconfig ninja docutils ];
|
|
buildInputs = [ fuse3 glib ];
|
|
checkInputs = [ which python3Packages.pytest ];
|
|
|
|
NIX_CFLAGS_COMPILE = stdenv.lib.optional
|
|
(stdenv.hostPlatform.system == "i686-linux")
|
|
"-D_FILE_OFFSET_BITS=64";
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/sbin
|
|
ln -sf $out/bin/sshfs $out/sbin/mount.sshfs
|
|
'';
|
|
|
|
#doCheck = true;
|
|
checkPhase = ''
|
|
# The tests need fusermount:
|
|
mkdir bin && cp ${fuse3}/bin/fusermount3 bin/fusermount
|
|
export PATH=bin:$PATH
|
|
# Can't access /dev/fuse within the sandbox: "FUSE kernel module does not seem to be loaded"
|
|
substituteInPlace test/util.py --replace "/dev/fuse" "/dev/null"
|
|
# TODO: "fusermount executable not setuid, and we are not root"
|
|
# We should probably use a VM test instead
|
|
python3 -m pytest test/
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
inherit (src.meta) homepage;
|
|
description = "FUSE-based filesystem that allows remote filesystems to be mounted over SSH";
|
|
platforms = platforms.linux;
|
|
license = licenses.gpl2;
|
|
maintainers = with maintainers; [ primeos ];
|
|
};
|
|
}
|