2a9336b426
The Elixir LS package in Nixpkgs by default used the latest Elixir
version available to compile and run Elixir LS. The user can build
a custom Elixir LS package with a different Elixir version:
my-custom-elixir-ls = pkgs.elixir-ls.override {
elixir = my-custom-elixir;
};
But by doing so the user changes only the Elixir version used to
run Elixir LS; the Elixir version used to compile Elixir LS doesn't
change. As the result, the custom Elixir LS package uses a different
Elixir version at runtime than the Elixir version it was compiled with.
In order to be able to modify the Elixir version used at build time,
I changed `mixRelease` and `fetchMixDeps` to accept `elixir` and
`hex` as parameters (defaults to the latest Elixir and Hex packages).
73 lines
2.4 KiB
Nix
73 lines
2.4 KiB
Nix
{ lib, elixir, fetchFromGitHub, fetchMixDeps, mixRelease }:
|
|
# Based on the work of Hauleth
|
|
# None of this would have happened without him
|
|
|
|
mixRelease rec {
|
|
pname = "elixir-ls";
|
|
version = "0.8.1";
|
|
inherit elixir;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "elixir-lsp";
|
|
repo = "elixir-ls";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-KlZq12RCor9GrwA8QMP3R+jUQ/xFHRjkLwwkvthiMU0=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
mixFodDeps = fetchMixDeps {
|
|
pname = "mix-deps-${pname}";
|
|
inherit src version elixir;
|
|
sha256 = "sha256-OzjToAg+q/ybCyqzNFk28OBsItjFTbdPi416EPh2qX0=";
|
|
};
|
|
|
|
# elixir_ls is an umbrella app
|
|
# override configurePhase to not skip umbrella children
|
|
configurePhase = ''
|
|
runHook preConfigure
|
|
mix deps.compile --no-deps-check
|
|
runHook postConfigure
|
|
'';
|
|
|
|
# elixir_ls require a special step for release
|
|
# compile and release need to be performed together because
|
|
# of the no-deps-check requirement
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
mix do compile --no-deps-check, elixir_ls.release
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/bin
|
|
cp -Rv release $out/lib
|
|
# Prepare the wrapper script
|
|
substitute release/language_server.sh $out/bin/elixir-ls \
|
|
--replace 'exec "''${dir}/launch.sh"' "exec $out/lib/launch.sh"
|
|
chmod +x $out/bin/elixir-ls
|
|
# prepare the launcher
|
|
substituteInPlace $out/lib/launch.sh \
|
|
--replace "ERL_LIBS=\"\$SCRIPTPATH:\$ERL_LIBS\"" \
|
|
"ERL_LIBS=$out/lib:\$ERL_LIBS" \
|
|
--replace "exec elixir" "exec ${elixir}/bin/elixir"
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/elixir-lsp/elixir-ls";
|
|
description = ''
|
|
A frontend-independent IDE "smartness" server for Elixir.
|
|
Implements the "Language Server Protocol" standard and provides debugger support via the "Debug Adapter Protocol"
|
|
'';
|
|
longDescription = ''
|
|
The Elixir Language Server provides a server that runs in the background, providing IDEs, editors, and other tools with information about Elixir Mix projects.
|
|
It adheres to the Language Server Protocol, a standard for frontend-independent IDE support.
|
|
Debugger integration is accomplished through the similar VS Code Debug Protocol.
|
|
'';
|
|
license = licenses.asl20;
|
|
platforms = platforms.unix;
|
|
maintainers = teams.beam.members;
|
|
};
|
|
passthru.updateScript = ./update.sh;
|
|
}
|