36497c2fde
Use dotnet core instead of mono, change license to gpl3Only, add test passthru and create update script
50 lines
1.6 KiB
Nix
50 lines
1.6 KiB
Nix
{ lib, stdenv, fetchurl, mono, libmediainfo, sqlite, curl, makeWrapper, icu, dotnetCorePackages, openssl, nixosTests }:
|
|
|
|
let
|
|
os = if stdenv.isDarwin then "osx" else "linux";
|
|
arch = {
|
|
x86_64-linux = "x64";
|
|
aarch64-linux = "arm64";
|
|
x86_64-darwin = "x64";
|
|
}."${stdenv.hostPlatform.system}" or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
|
|
|
|
hash = {
|
|
x64-linux_hash = "sha256-bTh+Z5w5ZkL2iPteStqVcoFDGZIbpVjuXn20TZsfgtY=";
|
|
arm64-linux_hash = "sha256-aIzVSIRuGNiIFJPToXCQwYsbICKuPtwKATnQhkxvJuA=";
|
|
x64-osx_hash = "sha256-FxRSAJvRQya2x1kei6yRceGcyQ2mCaFveyeMGw0Jqw4=";
|
|
}."${arch}-${os}_hash";
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "radarr";
|
|
version = "3.0.2.4552";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/Radarr/Radarr/releases/download/v${version}/Radarr.master.${version}.${os}-core-${arch}.tar.gz";
|
|
sha256 = hash;
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/{bin,share/${pname}-${version}}
|
|
cp -r * $out/share/${pname}-${version}/.
|
|
|
|
makeWrapper "${dotnetCorePackages.netcore_3_1}/bin/dotnet" $out/bin/Radarr \
|
|
--add-flags "$out/share/${pname}-${version}/Radarr.dll" \
|
|
--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [
|
|
curl sqlite libmediainfo mono openssl icu ]}
|
|
'';
|
|
|
|
passthru = {
|
|
updateScript = ./update.sh;
|
|
tests.smoke-test = nixosTests.radarr;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "A Usenet/BitTorrent movie downloader";
|
|
homepage = "https://radarr.video/";
|
|
license = licenses.gpl3Only;
|
|
maintainers = with maintainers; [ edwtjo purcell ];
|
|
platforms = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" ];
|
|
};
|
|
}
|