13352f28d2
This adds the following new packages: + elasticsearch7 + elasticsearch7-oss + logstash7 + logstash7-oss + kibana7 + kibana7-oss + filebeat7 + heartbeat7 + metricbeat7 + packetbeat7 + journalbeat7 The default major version of the ELK stack stays at 6. We should probably set it to 7 in a next commit.
49 lines
1.8 KiB
Nix
49 lines
1.8 KiB
Nix
{ stdenv, fetchFromGitHub, elk7Version, buildGoPackage, libpcap, systemd }:
|
|
|
|
let beat = package : extraArgs : buildGoPackage (rec {
|
|
name = "${package}-${version}";
|
|
version = elk7Version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "elastic";
|
|
repo = "beats";
|
|
rev = "v${version}";
|
|
sha256 = "0n1sjngc82b7wysw5aaiqvllq4c8rx2jj7khw4vrypc40f8ahjs5";
|
|
};
|
|
|
|
goPackagePath = "github.com/elastic/beats";
|
|
|
|
subPackages = [ package ];
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://www.elastic.co/products/beats;
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ fadenb basvandijk ];
|
|
platforms = platforms.linux;
|
|
};
|
|
} // extraArgs);
|
|
in {
|
|
filebeat7 = beat "filebeat" {meta.description = "Lightweight shipper for logfiles";};
|
|
heartbeat7 = beat "heartbeat" {meta.description = "Lightweight shipper for uptime monitoring";};
|
|
metricbeat7 = beat "metricbeat" {meta.description = "Lightweight shipper for metrics";};
|
|
packetbeat7 = beat "packetbeat" {
|
|
buildInputs = [ libpcap ];
|
|
meta.description = "Network packet analyzer that ships data to Elasticsearch";
|
|
meta.longDescription = ''
|
|
Packetbeat is an open source network packet analyzer that ships the
|
|
data to Elasticsearch.
|
|
|
|
Think of it like a distributed real-time Wireshark with a lot more
|
|
analytics features. The Packetbeat shippers sniff the traffic between
|
|
your application processes, parse on the fly protocols like HTTP, MySQL,
|
|
PostgreSQL, Redis or Thrift and correlate the messages into transactions.
|
|
'';
|
|
};
|
|
journalbeat7 = beat "journalbeat" {
|
|
meta.description = ''
|
|
Journalbeat is an open source data collector to read and forward
|
|
journal entries from Linuxes with systemd.
|
|
'';
|
|
buildInputs = [ systemd.dev ];
|
|
};
|
|
}
|