f6dca95c5d
The tsm-client needs a tsm-server to do anything useful. Without a server, automated tests can just check diagnostic outputs for plausibility. The commit at hand adds two tests: 1. The command line interface `dsmc` is called, then it is verified that the program does * report the correct client version, * find its configuration file, * report a connection error. 2. To check the GUI (and the tsm-client nixos module), we add a vm test which uses the module to install `tsm-client-withGui`. To verify that the GUI's basic functionality is present, we skip over all connection failure related error messages and open the "Connection Information" dialog from the main application window. This dialog presents the node name and the client version; both are verified by the test. Note: Our `tsm-client` build recipe consists of two packages: The "unwrapped" package and the final package. This commit puts the unwrapped one into the final package's `passthru` so that tests can access the original version string that is needed to check the client version reported by the application.
57 lines
1.8 KiB
Nix
57 lines
1.8 KiB
Nix
# The tsm-client GUI first tries to connect to a server.
|
|
# We can't simulate a server, so we just check if
|
|
# it reports the correct connection failure error.
|
|
# After that the test persuades the GUI
|
|
# to show its main application window
|
|
# and verifies some configuration information.
|
|
|
|
import ./make-test-python.nix ({ lib, pkgs, ... }: {
|
|
name = "tsm-client";
|
|
|
|
enableOCR = true;
|
|
|
|
machine = { pkgs, ... }: {
|
|
imports = [ ./common/x11.nix ];
|
|
programs.tsmClient = {
|
|
enable = true;
|
|
package = pkgs.tsm-client-withGui;
|
|
defaultServername = "testserver";
|
|
servers.testserver = {
|
|
# 192.0.0.8 is a "dummy address" according to RFC 7600
|
|
server = "192.0.0.8";
|
|
node = "SOME-NODE";
|
|
passwdDir = "/tmp";
|
|
};
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
machine.succeed("which dsmj") # fail early if this is missing
|
|
machine.wait_for_x()
|
|
machine.execute("DSM_LOG=/tmp dsmj -optfile=/dev/null >&2 &")
|
|
|
|
# does it report the "TCP/IP connection failure" error code?
|
|
machine.wait_for_window("IBM Spectrum Protect")
|
|
machine.wait_for_text("ANS2610S")
|
|
machine.send_key("esc")
|
|
|
|
# it asks to continue to restore a local backupset now;
|
|
# "yes" (return) leads to the main application window
|
|
machine.wait_for_text("backupset")
|
|
machine.send_key("ret")
|
|
|
|
# main window: navigate to "Connection Information"
|
|
machine.wait_for_text("Welcome")
|
|
machine.send_key("alt-f") # "File" menu
|
|
machine.send_key("c") # "Connection Information"
|
|
|
|
# "Connection Information" dialog box
|
|
machine.wait_for_window("Connection Information")
|
|
machine.wait_for_text("SOME-NODE")
|
|
machine.wait_for_text("${pkgs.tsm-client.passthru.unwrapped.version}")
|
|
|
|
machine.shutdown()
|
|
'';
|
|
|
|
meta.maintainers = [ lib.maintainers.yarny ];
|
|
})
|