4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
59 lines
1.9 KiB
Nix
59 lines
1.9 KiB
Nix
{ stdenv, lib, fetchzip, substituteAll, dpkg, autoPatchelfHook, cups, tcl, tk, xorg, makeWrapper }:
|
||
let
|
||
debPlatform =
|
||
if stdenv.hostPlatform.system == "x86_64-linux" then "amd64"
|
||
else if stdenv.hostPlatform.system == "i686-linux" then "i386"
|
||
else throw "Unsupported system: ${stdenv.hostPlatform.system}";
|
||
in
|
||
stdenv.mkDerivation rec {
|
||
pname = "fxlinuxprintutil";
|
||
version = "1.1.1-1";
|
||
|
||
src = fetchzip {
|
||
url = "https://onlinesupport.fujixerox.com/driver_downloads/fxlinuxpdf112119031.zip";
|
||
sha256 = "1mv07ch6ysk9bknfmjqsgxb803sj6vfin29s9knaqv17jvgyh0n3";
|
||
curlOpts = "--user-agent Mozilla/5.0"; # HTTP 410 otherwise
|
||
};
|
||
|
||
patches = [
|
||
# replaces references to “path/to/fxlputil” via $0 that are broken by our wrapProgram
|
||
# with /nix/store/fxlinuxprintutil/bin/fxlputil
|
||
./fxlputil.patch
|
||
|
||
# replaces the code that looks for Tcl packages in the working directory and /usr/lib
|
||
# or /usr/lib64 with /nix/store/fxlinuxprintutil/lib
|
||
./fxlputil.tcl.patch
|
||
|
||
# replaces the code that looks for X11’s locale.alias in /usr/share/X11/locale or
|
||
# /usr/lib/X11/locale with /nix/store/libX11/share/X11/locale
|
||
(substituteAll {
|
||
src = ./fxlocalechk.tcl.patch;
|
||
inherit (xorg) libX11;
|
||
})
|
||
];
|
||
|
||
nativeBuildInputs = [ dpkg autoPatchelfHook makeWrapper ];
|
||
buildInputs = [ cups tcl tk ];
|
||
|
||
sourceRoot = ".";
|
||
unpackCmd = "dpkg-deb -x $curSrc/${pname}_${version}_${debPlatform}.deb .";
|
||
|
||
dontConfigure = true;
|
||
dontBuild = true;
|
||
|
||
installPhase = ''
|
||
mkdir -p $out
|
||
mv usr/bin $out
|
||
mv usr/lib $out
|
||
|
||
wrapProgram $out/bin/fxlputil --prefix PATH : ${lib.makeBinPath [ tcl tk ]}
|
||
'';
|
||
|
||
meta = with lib; {
|
||
description = "Optional configuration tool for fxlinuxprint";
|
||
homepage = "https://onlinesupport.fujixerox.com";
|
||
license = licenses.unfree;
|
||
maintainers = with maintainers; [ delan ];
|
||
platforms = platforms.linux;
|
||
};
|
||
}
|