c6588dd341
vifm includes some optional features what are currently no-op due to missing dependencies. Once such example is `vifm-media`. vimfm-media is a Linux script included with vifm which can be used to mount/umount removable media from within vifm. However, vifm-media has additional dependencies, namely Python, dbus, and a supported back-end such as udisks2. While vimfm-media is currently installed, it fails with the error "No supported backend found." This change adds optional support for vifm-media via the new package vifm-full; Opening for the opportunity to add whatever optional dependencies I have not considered in this change in the future, while not generously increasing the closure size of the original vifm package. For reference, vifm has a closure size of 41,164,432 while the new vifm-full increases this to 382,642,536. Calculated with `nix path-info -S` Note: While vifm-media supports numerous back-ends, this change only adds support for udisks2. In addition, vifm-media is not supported on MacOS/OSX, for which upstream provides an alternative script.
45 lines
1.4 KiB
Nix
45 lines
1.4 KiB
Nix
{ stdenv, fetchurl, makeWrapper
|
|
, pkgconfig
|
|
, ncurses, libX11
|
|
, utillinux, file, which, groff
|
|
|
|
# adds support for handling removable media (vifm-media). Linux only!
|
|
, mediaSupport ? false, python3 ? null, udisks2 ? null, lib ? null
|
|
}:
|
|
|
|
let isFullPackage = mediaSupport;
|
|
in stdenv.mkDerivation rec {
|
|
pname = if isFullPackage then "vifm-full" else "vifm";
|
|
version = "0.10.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/vifm/vifm/releases/download/v${version}/vifm-${version}.tar.bz2";
|
|
sha256 = "0fyhxh7ndjn8fyjhj14ymkr3pjcs3k1xbs43g7xvvq85vdb6y04r";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig makeWrapper ];
|
|
buildInputs = [ ncurses libX11 utillinux file which groff ];
|
|
|
|
postFixup = let
|
|
path = lib.makeBinPath
|
|
[ udisks2
|
|
(python3.withPackages (p: [p.dbus-python]))
|
|
];
|
|
|
|
wrapVifmMedia = "wrapProgram $out/share/vifm/vifm-media --prefix PATH : ${path}";
|
|
in ''
|
|
${if mediaSupport then wrapVifmMedia else ""}
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = ''A vi-like file manager${if isFullPackage then "; Includes support for optional features" else ""}'';
|
|
maintainers = with maintainers; [ raskin ];
|
|
platforms = if mediaSupport then platforms.linux else platforms.unix;
|
|
license = licenses.gpl2;
|
|
downloadPage = "https://vifm.info/downloads.shtml";
|
|
homepage = https://vifm.info/;
|
|
inherit version;
|
|
updateWalker = true;
|
|
};
|
|
}
|
|
|