39f357a836
* slurm: 17.11.5 -> 17.11.7, pyslurm: 20180427 -> 20180604 This commit also swaps to use the official repository's github release tags instead of their download site, which only keeps the most recent version with no historical archives. * Document why we don't run tests * Remove dead testing code
70 lines
2.2 KiB
Nix
70 lines
2.2 KiB
Nix
{ stdenv, fetchFromGitHub, pkgconfig, libtool, curl
|
|
, python, munge, perl, pam, openssl
|
|
, ncurses, mysql, gtk2, lua, hwloc, numactl
|
|
, readline, freeipmi, libssh2, xorg
|
|
# enable internal X11 support via libssh2
|
|
, enableX11 ? true
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "slurm-${version}";
|
|
version = "17.11.7";
|
|
|
|
# N.B. We use github release tags instead of https://www.schedmd.com/downloads.php
|
|
# because the latter does not keep older releases.
|
|
src = fetchFromGitHub {
|
|
owner = "SchedMD";
|
|
repo = "slurm";
|
|
# The release tags use - instead of ., and have an extra -1 suffix.
|
|
rev = "${builtins.replaceStrings ["."] ["-"] name}-1";
|
|
sha256 = "00dgirjd75i1x6pj80avp18hx5gr3dsnh13vbkqbf0iwpd72qyhp";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
prePatch = stdenv.lib.optional enableX11 ''
|
|
substituteInPlace src/common/x11_util.c \
|
|
--replace '"/usr/bin/xauth"' '"${xorg.xauth}/bin/xauth"'
|
|
'';
|
|
|
|
# nixos test fails to start slurmd with 'undefined symbol: slurm_job_preempt_mode'
|
|
# https://groups.google.com/forum/#!topic/slurm-devel/QHOajQ84_Es
|
|
# this doesn't fix tests completely at least makes slurmd to launch
|
|
hardeningDisable = [ "bindnow" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig libtool ];
|
|
buildInputs = [
|
|
curl python munge perl pam openssl
|
|
mysql.connector-c ncurses gtk2
|
|
lua hwloc numactl readline freeipmi
|
|
] ++ stdenv.lib.optionals enableX11 [ libssh2 xorg.xauth ];
|
|
|
|
configureFlags = with stdenv.lib;
|
|
[ "--with-munge=${munge}"
|
|
"--with-ssl=${openssl.dev}"
|
|
"--with-hwloc=${hwloc.dev}"
|
|
"--with-freeipmi=${freeipmi}"
|
|
"--sysconfdir=/etc/slurm"
|
|
] ++ (optional (gtk2 == null) "--disable-gtktest")
|
|
++ (optional enableX11 "--with-libssh2=${libssh2.dev}");
|
|
|
|
|
|
preConfigure = ''
|
|
patchShebangs ./doc/html/shtml2html.py
|
|
patchShebangs ./doc/man/man2html.py
|
|
'';
|
|
|
|
postInstall = ''
|
|
rm -f $out/lib/*.la $out/lib/slurm/*.la
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = http://www.schedmd.com/;
|
|
description = "Simple Linux Utility for Resource Management";
|
|
platforms = platforms.linux;
|
|
license = licenses.gpl2;
|
|
maintainers = with maintainers; [ jagajaga markuskowa ];
|
|
};
|
|
}
|