0bac188b59
- enable telepathy again - fix build with libsoup, pulled in through folks_eds. Probably caused by libsoup version bump, but not sure.
61 lines
1.9 KiB
Nix
61 lines
1.9 KiB
Nix
{ stdenv, gettext, fetchurl, evolution-data-server
|
||
, pkgconfig, libxslt, docbook_xsl, docbook_xml_dtd_42, python3, gtk3, glib, cheese
|
||
, libchamplain, clutter-gtk, geocode-glib, gnome-desktop, gnome-online-accounts
|
||
, wrapGAppsHook, folks, libxml2, gnome3, telepathy-glib
|
||
, vala, meson, ninja, libhandy }:
|
||
|
||
let
|
||
version = "3.32";
|
||
in stdenv.mkDerivation rec {
|
||
name = "gnome-contacts-${version}";
|
||
|
||
src = fetchurl {
|
||
url = "mirror://gnome/sources/gnome-contacts/${stdenv.lib.versions.majorMinor version}/${name}.tar.xz";
|
||
sha256 = "12vr75d5akhs0fzmjg6j21jrrlr8njdrf9dwhw94k8p73y1gjjgw";
|
||
};
|
||
|
||
propagatedUserEnvPkgs = [ evolution-data-server ];
|
||
|
||
nativeBuildInputs = [
|
||
meson ninja pkgconfig vala gettext libxslt docbook_xsl docbook_xml_dtd_42 python3 wrapGAppsHook
|
||
];
|
||
|
||
buildInputs = [
|
||
gtk3 glib evolution-data-server gnome3.gsettings-desktop-schemas
|
||
folks gnome-desktop telepathy-glib libhandy
|
||
libxml2 gnome-online-accounts cheese
|
||
gnome3.adwaita-icon-theme libchamplain clutter-gtk geocode-glib
|
||
];
|
||
|
||
mesonFlags = [
|
||
"-Dtelepathy=true"
|
||
];
|
||
|
||
postPatch = ''
|
||
chmod +x build-aux/meson_post_install.py
|
||
patchShebangs build-aux/meson_post_install.py
|
||
'';
|
||
|
||
# In file included from src/gnome-contacts@exe/contacts-avatar-selector.c:30:0:
|
||
# /nix/store/*-cheese-3.28.0/include/cheese/cheese-widget.h:26:10: fatal error: clutter-gtk/clutter-gtk.h: No such file or directory
|
||
# #include <clutter-gtk/clutter-gtk.h>
|
||
# ^~~~~~~~~~~~~~~~~~~~~~~~~~~
|
||
NIX_CFLAGS_COMPILE = "-I${stdenv.lib.getDev clutter-gtk}/include/clutter-gtk-1.0";
|
||
|
||
doCheck = true;
|
||
|
||
passthru = {
|
||
updateScript = gnome3.updateScript {
|
||
packageName = "gnome-contacts";
|
||
attrPath = "gnome3.gnome-contacts";
|
||
};
|
||
};
|
||
|
||
meta = with stdenv.lib; {
|
||
homepage = https://wiki.gnome.org/Apps/Contacts;
|
||
description = "GNOME’s integrated address book";
|
||
maintainers = gnome3.maintainers;
|
||
license = licenses.gpl2;
|
||
platforms = platforms.linux;
|
||
};
|
||
}
|