002c411f45
See notes for this and previous release: * https://github.com/intel/libva/releases/tag/2.3.0 * https://github.com/intel/libva/releases/tag/2.2.0
45 lines
1.3 KiB
Nix
45 lines
1.3 KiB
Nix
{ stdenv, lib, fetchFromGitHub, autoreconfHook, pkgconfig
|
|
, libXext, libdrm, libXfixes, wayland, libffi, libX11
|
|
, libGL, libGL_driver
|
|
, minimal ? false, libva-minimal
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "libva-${lib.optionalString minimal "minimal-"}${version}";
|
|
version = "2.3.0";
|
|
|
|
# update libva-utils and vaapiIntel as well
|
|
src = fetchFromGitHub {
|
|
owner = "01org";
|
|
repo = "libva";
|
|
rev = version;
|
|
sha256 = "0zip22b5qwyjygsmrmjq62hdpl9z77d84h5hni8cn6xz5cmbw29z";
|
|
};
|
|
|
|
outputs = [ "dev" "out" ];
|
|
|
|
nativeBuildInputs = [ autoreconfHook pkgconfig ];
|
|
|
|
buildInputs = [ libdrm ]
|
|
++ lib.optionals (!minimal) [ libva-minimal libX11 libXext libXfixes wayland libffi libGL ];
|
|
# TODO: share libs between minimal and !minimal - perhaps just symlink them
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
configureFlags = [
|
|
# Add FHS paths for non-NixOS applications.
|
|
"--with-drivers-path=${libGL_driver.driverLink}/lib/dri:/usr/lib/dri:/usr/lib32/dri"
|
|
] ++ lib.optionals (!minimal) [ "--enable-glx" ];
|
|
|
|
installFlags = [
|
|
"dummy_drv_video_ladir=$(out)/lib/dri"
|
|
];
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "VAAPI library: Video Acceleration API";
|
|
homepage = http://www.freedesktop.org/wiki/Software/vaapi;
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ garbas ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|