72255d3fef
Updating the latest version of gmrender-resurrect lets us skip adding the cherrypick patch, as this is already included in 0.0.9. (Note, I am not maintainer of this nix package, but maintainer of gmrender-resurrect) Signed-off-by: Henner Zeller <h.zeller@acm.org>
38 lines
1.3 KiB
Nix
38 lines
1.3 KiB
Nix
{ lib, stdenv, fetchFromGitHub, autoreconfHook, pkg-config, makeWrapper, gstreamer
|
|
, gst-plugins-base, gst-plugins-good, gst-plugins-bad, gst-plugins-ugly, gst-libav, libupnp }:
|
|
|
|
let
|
|
version = "0.0.9";
|
|
|
|
makePluginPath = plugins: builtins.concatStringsSep ":" (map (p: p + "/lib/gstreamer-1.0") plugins);
|
|
|
|
pluginPath = makePluginPath [ gstreamer gst-plugins-base gst-plugins-good gst-plugins-bad gst-plugins-ugly gst-libav ];
|
|
in
|
|
stdenv.mkDerivation {
|
|
pname = "gmrender-resurrect";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "hzeller";
|
|
repo = "gmrender-resurrect";
|
|
rev = "v${version}";
|
|
sha256 = "0byxd28hnhkhf3lqsad43n6czfajvc1ksg9zikxb95wwk4ljqv1q";
|
|
};
|
|
|
|
buildInputs = [ gstreamer libupnp ];
|
|
nativeBuildInputs = [ autoreconfHook pkg-config makeWrapper ];
|
|
|
|
postInstall = ''
|
|
for prog in "$out/bin/"*; do
|
|
wrapProgram "$prog" --suffix GST_PLUGIN_SYSTEM_PATH_1_0 : "${pluginPath}"
|
|
done
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Resource efficient UPnP/DLNA renderer, optimal for Raspberry Pi, CuBox or a general MediaServer";
|
|
homepage = "https://github.com/hzeller/gmrender-resurrect";
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ koral hzeller ];
|
|
};
|
|
}
|