bf17d6dacf
[N.B., this package also applies to the commits that follow it in the same
PR.]
In most cases, buildPackages = pkgs so things work just as before. For
cross compiling, however, buildPackages is resolved as the previous
bootstrapping stage. This allows us to avoid the mkDerivation hacks cross
compiling currently uses today.
To avoid a massive refactor, callPackage will splice together both package
sets. Again to avoid churn, it uses the old `nativeDrv` vs `crossDrv` to do
so. So now, whether cross compiling or not, packages with get a `nativeDrv`
and `crossDrv`---in the non-cross-compiling case they are simply the same
derivation. This is good because it reduces the divergence between the
cross and non-cross dataflow. See `pkgs/top-level/splice.nix` for a comment
along the lines of the preceding paragraph, and the code that does this
splicing.
Also, `forceNativeDrv` is replaced with `forceNativePackages`. The latter
resolves `pkgs` unless the host platform is different from the build
platform, in which case it resolves to `buildPackages`. Note that the
target platform is not important here---it will not prevent
`forcedNativePackages` from resolving to `pkgs`.
--------
Temporarily, we make preserve some dubious decisions in the name of preserving
hashes:
Most importantly, we don't distinguish between "host" and "target" in the
autoconf sense. This leads to the proliferation of *Cross derivations
currently used. What we ought to is resolve native deps of the cross "build
packages" (build = host != target) package set against the "vanilla
packages" (build = host = target) package set. Instead, "build packages"
uses itself, with (informally) target != build in all cases.
This is wrong because it violates the "sliding window" principle of
bootstrapping stages that shifting the platform triple of one stage to the
left coincides with the next stage's platform triple. Only because we don't
explicitly distinguish between "host" and "target" does it appear that the
"sliding window" principle is preserved--indeed it is over the reductionary
"platform double" of just "build" and "host/target".
Additionally, we build libc, libgcc, etc in the same stage as the compilers
themselves, which is wrong because they are used at runtime, not build
time. Fixing this is somewhat subtle, and the solution and problem will be
better explained in the commit that does fix it.
Commits after this will solve both these issues, at the expense of breaking
cross hashes. Native hashes won't be broken, thankfully.
--------
Did the temporary ugliness pan out? Of the packages that currently build in
`release-cross.nix`, the only ones that have their hash changed are
`*.gcc.crossDrv` and `bootstrapTools.*.coreutilsMinimal`. In both cases I
think it doesn't matter.
1. GCC when doing a `build = host = target = foreign` build (maximally
cross), still defines environment variables like `CPATH`[1] with
packages. This seems assuredly wrong because whether gcc dynamically
links those, or the programs built by gcc dynamically link those---I
have no idea which case is reality---they should be foreign. Therefore,
in all likelihood, I just made the gcc less broken.
2. Coreutils (ab)used the old cross-compiling infrastructure to depend on
a native version of itself. When coreutils was overwritten to be built
with fewer features, the native version it used would also be
overwritten because the binding was tight. Now it uses the much looser
`BuildPackages.coreutils` which is just fine as a richer build dep
doesn't cause any problems and avoids a rebuild.
So, in conclusion I'd say the conservatism payed off. Onward to actually
raking the muck in the next PR!
[1]: https://gcc.gnu.org/onlinedocs/gcc/Environment-Variables.html
204 lines
6 KiB
Nix
204 lines
6 KiB
Nix
|
|
{ # The platforms for which we build Nixpkgs.
|
|
supportedSystems ? [ builtins.currentSystem ]
|
|
, # Strip most of attributes when evaluating to spare memory usage
|
|
scrubJobs ? true
|
|
}:
|
|
|
|
with import ./release-lib.nix { inherit supportedSystems scrubJobs; };
|
|
|
|
let
|
|
inherit (pkgs) lib;
|
|
|
|
nativePlatforms = linux;
|
|
|
|
/* Basic list of packages to cross-build */
|
|
basicCrossDrv = {
|
|
gccCrossStageFinal = nativePlatforms;
|
|
bison.crossDrv = nativePlatforms;
|
|
busybox.crossDrv = nativePlatforms;
|
|
coreutils.crossDrv = nativePlatforms;
|
|
dropbear.crossDrv = nativePlatforms;
|
|
};
|
|
|
|
/* Basic list of packages to be natively built,
|
|
but need a crossSystem defined to get meaning */
|
|
basicNativeDrv = {
|
|
gdbCross.nativeDrv = nativePlatforms;
|
|
};
|
|
|
|
basic = basicCrossDrv // basicNativeDrv;
|
|
|
|
in
|
|
|
|
{
|
|
# These derivations from a cross package set's `buildPackages` should be
|
|
# identical to their vanilla equivalents --- none of these package should
|
|
# observe the target platform which is the only difference between those
|
|
# package sets.
|
|
ensureUnaffected = let
|
|
# Absurd values are fine here, as we are not building anything. In fact,
|
|
# there probably a good idea to try to be "more parametric" --- i.e. avoid
|
|
# any special casing.
|
|
crossSystem = {
|
|
config = "foosys";
|
|
libc = "foolibc";
|
|
};
|
|
|
|
# Converting to a string (drv path) before checking equality is probably a
|
|
# good idea lest there be some irrelevant pass-through debug attrs that
|
|
# cause false negatives.
|
|
testEqualOne = path: system: let
|
|
f = path: attrs: builtins.toString (lib.getAttrFromPath path (allPackages attrs));
|
|
in assert
|
|
f path { inherit system; }
|
|
==
|
|
f (["buildPackages"] ++ path) { inherit system crossSystem; };
|
|
true;
|
|
|
|
testEqual = path: systems: forAllSupportedSystems systems (testEqualOne path);
|
|
|
|
mapTestEqual = lib.mapAttrsRecursive testEqual;
|
|
|
|
in mapTestEqual {
|
|
boehmgc = nativePlatforms;
|
|
libffi = nativePlatforms;
|
|
libiconv = nativePlatforms;
|
|
libtool = nativePlatforms;
|
|
zlib = nativePlatforms;
|
|
readline = nativePlatforms;
|
|
libxml2 = nativePlatforms;
|
|
guile = nativePlatforms;
|
|
};
|
|
|
|
|
|
/* Test some cross builds to the Sheevaplug */
|
|
crossSheevaplugLinux = let
|
|
crossSystem = {
|
|
config = "armv5tel-unknown-linux-gnueabi";
|
|
bigEndian = false;
|
|
arch = "arm";
|
|
float = "soft";
|
|
withTLS = true;
|
|
platform = pkgs.platforms.sheevaplug;
|
|
libc = "glibc";
|
|
openssl.system = "linux-generic32";
|
|
};
|
|
in mapTestOnCross crossSystem (basic // {
|
|
ubootSheevaplug.crossDrv = nativePlatforms;
|
|
});
|
|
|
|
|
|
/* Test some cross builds on 32 bit mingw-w64 */
|
|
crossMingw32 = let
|
|
crossSystem = {
|
|
config = "i686-w64-mingw32";
|
|
arch = "x86"; # Irrelevant
|
|
libc = "msvcrt"; # This distinguishes the mingw (non posix) toolchain
|
|
platform = {};
|
|
};
|
|
in mapTestOnCross crossSystem {
|
|
coreutils.crossDrv = nativePlatforms;
|
|
boehmgc.crossDrv = nativePlatforms;
|
|
gmp.crossDrv = nativePlatforms;
|
|
guile_1_8.crossDrv = nativePlatforms;
|
|
libffi.crossDrv = nativePlatforms;
|
|
libtool.crossDrv = nativePlatforms;
|
|
libunistring.crossDrv = nativePlatforms;
|
|
windows.wxMSW.crossDrv = nativePlatforms;
|
|
};
|
|
|
|
|
|
/* Test some cross builds on 64 bit mingw-w64 */
|
|
crossMingwW64 = let
|
|
crossSystem = {
|
|
# That's the triplet they use in the mingw-w64 docs.
|
|
config = "x86_64-w64-mingw32";
|
|
arch = "x86_64"; # Irrelevant
|
|
libc = "msvcrt"; # This distinguishes the mingw (non posix) toolchain
|
|
platform = {};
|
|
};
|
|
in mapTestOnCross crossSystem {
|
|
coreutils.crossDrv = nativePlatforms;
|
|
boehmgc.crossDrv = nativePlatforms;
|
|
gmp.crossDrv = nativePlatforms;
|
|
guile_1_8.crossDrv = nativePlatforms;
|
|
libffi.crossDrv = nativePlatforms;
|
|
libtool.crossDrv = nativePlatforms;
|
|
libunistring.crossDrv = nativePlatforms;
|
|
windows.wxMSW.crossDrv = nativePlatforms;
|
|
};
|
|
|
|
|
|
/* Linux on the fuloong */
|
|
fuloongminipc = let
|
|
crossSystem = {
|
|
config = "mips64el-unknown-linux";
|
|
bigEndian = false;
|
|
arch = "mips";
|
|
float = "hard";
|
|
withTLS = true;
|
|
libc = "glibc";
|
|
platform = {
|
|
name = "fuloong-minipc";
|
|
kernelMajor = "2.6";
|
|
kernelBaseConfig = "lemote2f_defconfig";
|
|
kernelHeadersBaseConfig = "fuloong2e_defconfig";
|
|
uboot = null;
|
|
kernelArch = "mips";
|
|
kernelAutoModules = false;
|
|
kernelTarget = "vmlinux";
|
|
};
|
|
openssl.system = "linux-generic32";
|
|
gcc = {
|
|
arch = "loongson2f";
|
|
abi = "n32";
|
|
};
|
|
};
|
|
in mapTestOnCross crossSystem {
|
|
coreutils.crossDrv = nativePlatforms;
|
|
ed.crossDrv = nativePlatforms;
|
|
patch.crossDrv = nativePlatforms;
|
|
};
|
|
|
|
|
|
/* Linux on Raspberrypi */
|
|
rpi = let
|
|
crossSystem = {
|
|
config = "armv6l-unknown-linux-gnueabi";
|
|
bigEndian = false;
|
|
arch = "arm";
|
|
float = "hard";
|
|
fpu = "vfp";
|
|
withTLS = true;
|
|
libc = "glibc";
|
|
platform = pkgs.platforms.raspberrypi;
|
|
openssl.system = "linux-generic32";
|
|
gcc = {
|
|
arch = "armv6";
|
|
fpu = "vfp";
|
|
float = "softfp";
|
|
abi = "aapcs-linux";
|
|
};
|
|
};
|
|
in mapTestOnCross crossSystem {
|
|
coreutils.crossDrv = nativePlatforms;
|
|
ed.crossDrv = nativePlatforms;
|
|
patch.crossDrv = nativePlatforms;
|
|
vim.crossDrv = nativePlatforms;
|
|
unzip.crossDrv = nativePlatforms;
|
|
ddrescue.crossDrv = nativePlatforms;
|
|
lynx.crossDrv = nativePlatforms;
|
|
patchelf.crossDrv = nativePlatforms;
|
|
binutils.crossDrv = nativePlatforms;
|
|
mpg123.crossDrv = nativePlatforms;
|
|
};
|
|
|
|
|
|
/* Cross-built bootstrap tools for every supported platform */
|
|
bootstrapTools = let
|
|
tools = import ../stdenv/linux/make-bootstrap-tools-cross.nix { system = "x86_64-linux"; };
|
|
maintainers = [ lib.maintainers.dezgeg ];
|
|
mkBootstrapToolsJob = drv: hydraJob' (lib.addMetaAttrs { inherit maintainers; } drv);
|
|
in lib.mapAttrsRecursiveCond (as: !lib.isDerivation as) (name: mkBootstrapToolsJob) tools;
|
|
}
|