160 lines
5 KiB
Nix
160 lines
5 KiB
Nix
{ fetchurl, stdenv, squashfsTools, xorg, alsaLib, makeWrapper, openssl, freetype
|
|
, glib, pango, cairo, atk, gdk_pixbuf, gtk2, cups, nspr, nss, libpng
|
|
, libgcrypt, systemd, fontconfig, dbus, expat, ffmpeg, curl, zlib, gnome3
|
|
, at-spi2-atk
|
|
}:
|
|
|
|
let
|
|
# TO UPDATE: just execute the ./update.sh script (won't do anything if there is no update)
|
|
# "rev" decides what is actually being downloaded
|
|
version = "1.0.96.181.gf6bc1b6b-12";
|
|
# To get the latest stable revision:
|
|
# curl -H 'X-Ubuntu-Series: 16' 'https://api.snapcraft.io/api/v1/snaps/details/spotify?channel=stable' | jq '.download_url,.version,.last_updated'
|
|
# To get general information:
|
|
# curl -H 'Snap-Device-Series: 16' 'https://api.snapcraft.io/v2/snaps/info/spotify' | jq '.'
|
|
# More examples of api usage:
|
|
# https://github.com/canonical-websites/snapcraft.io/blob/master/webapp/publisher/snaps/views.py
|
|
rev = "30";
|
|
|
|
|
|
deps = [
|
|
alsaLib
|
|
atk
|
|
at-spi2-atk
|
|
cairo
|
|
cups
|
|
curl
|
|
dbus
|
|
expat
|
|
ffmpeg
|
|
fontconfig
|
|
freetype
|
|
gdk_pixbuf
|
|
glib
|
|
gtk2
|
|
libgcrypt
|
|
libpng
|
|
nss
|
|
pango
|
|
stdenv.cc.cc
|
|
systemd
|
|
xorg.libX11
|
|
xorg.libXcomposite
|
|
xorg.libXcursor
|
|
xorg.libXdamage
|
|
xorg.libXext
|
|
xorg.libXfixes
|
|
xorg.libXi
|
|
xorg.libXrandr
|
|
xorg.libXrender
|
|
xorg.libXScrnSaver
|
|
xorg.libXtst
|
|
xorg.libxcb
|
|
zlib
|
|
];
|
|
|
|
in
|
|
|
|
stdenv.mkDerivation {
|
|
name = "spotify-${version}";
|
|
|
|
# fetch from snapcraft instead of the debian repository most repos fetch from.
|
|
# That is a bit more cumbersome. But the debian repository only keeps the last
|
|
# two versions, while snapcraft should provide versions indefinately:
|
|
# https://forum.snapcraft.io/t/how-can-a-developer-remove-her-his-app-from-snap-store/512
|
|
|
|
# This is the next-best thing, since we're not allowed to re-distribute
|
|
# spotify ourselves:
|
|
# https://community.spotify.com/t5/Desktop-Linux/Redistribute-Spotify-on-Linux-Distributions/td-p/1695334
|
|
src = fetchurl {
|
|
url = "https://api.snapcraft.io/api/v1/snaps/download/pOBIoZ2LrCB3rDohMxoYGnbN14EHOgD7_${rev}.snap";
|
|
sha512 = "859730fbc80067f0828f7e13eee9a21b13b749f897a50e17c2da4ee672785cfd79e1af6336e609529d105e040dc40f61b6189524783ac93d49f991c4ea8b3c56";
|
|
};
|
|
|
|
buildInputs = [ squashfsTools makeWrapper ];
|
|
|
|
doConfigure = false;
|
|
doBuild = false;
|
|
dontStrip = true;
|
|
dontPatchELF = true;
|
|
|
|
unpackPhase = ''
|
|
runHook preUnpack
|
|
unsquashfs "$src" '/usr/share/spotify' '/usr/bin/spotify' '/meta/snap.yaml'
|
|
cd squashfs-root
|
|
if ! grep -q 'grade: stable' meta/snap.yaml; then
|
|
# Unfortunately this check is not reliable: At the moment (2018-07-26) the
|
|
# latest version in the "edge" channel is also marked as stable.
|
|
echo "The snap package is marked as unstable:"
|
|
grep 'grade: ' meta/snap.yaml
|
|
echo "You probably chose the wrong revision."
|
|
exit 1
|
|
fi
|
|
if ! grep -q '${version}' meta/snap.yaml; then
|
|
echo "Package version differs from version found in snap metadata:"
|
|
grep 'version: ' meta/snap.yaml
|
|
echo "While the nix package specifies: ${version}."
|
|
echo "You probably chose the wrong revision or forgot to update the nix version."
|
|
exit 1
|
|
fi
|
|
runHook postUnpack
|
|
'';
|
|
|
|
installPhase =
|
|
''
|
|
runHook preInstall
|
|
|
|
libdir=$out/lib/spotify
|
|
mkdir -p $libdir
|
|
mv ./usr/* $out/
|
|
|
|
cp meta/snap.yaml $out
|
|
|
|
# Work around Spotify referring to a specific minor version of
|
|
# OpenSSL.
|
|
|
|
ln -s ${openssl.out}/lib/libssl.so $libdir/libssl.so.1.0.0
|
|
ln -s ${openssl.out}/lib/libcrypto.so $libdir/libcrypto.so.1.0.0
|
|
ln -s ${nspr.out}/lib/libnspr4.so $libdir/libnspr4.so
|
|
ln -s ${nspr.out}/lib/libplc4.so $libdir/libplc4.so
|
|
|
|
ln -s ${ffmpeg.out}/lib/libavcodec.so.56 $libdir/libavcodec-ffmpeg.so.56
|
|
ln -s ${ffmpeg.out}/lib/libavformat.so.56 $libdir/libavformat-ffmpeg.so.56
|
|
|
|
rpath="$out/share/spotify:$libdir"
|
|
|
|
patchelf \
|
|
--interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
|
|
--set-rpath $rpath $out/share/spotify/spotify
|
|
|
|
librarypath="${stdenv.lib.makeLibraryPath deps}:$libdir"
|
|
wrapProgram $out/share/spotify/spotify \
|
|
--prefix LD_LIBRARY_PATH : "$librarypath" \
|
|
--prefix PATH : "${gnome3.zenity}/bin"
|
|
|
|
# fix Icon line in the desktop file (#48062)
|
|
sed -i "s:^Icon=.*:Icon=spotify-client:" "$out/share/spotify/spotify.desktop"
|
|
|
|
# Desktop file
|
|
mkdir -p "$out/share/applications/"
|
|
cp "$out/share/spotify/spotify.desktop" "$out/share/applications/"
|
|
|
|
# Icons
|
|
for i in 16 22 24 32 48 64 128 256 512; do
|
|
ixi="$i"x"$i"
|
|
mkdir -p "$out/share/icons/hicolor/$ixi/apps"
|
|
ln -s "$out/share/spotify/icons/spotify-linux-$i.png" \
|
|
"$out/share/icons/hicolor/$ixi/apps/spotify-client.png"
|
|
done
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://www.spotify.com/;
|
|
description = "Play music from the Spotify music service";
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ eelco ftrvxmtrx sheenobu mudri ];
|
|
platforms = [ "x86_64-linux" ];
|
|
};
|
|
}
|