89023c38fc
I made a mistake merge. Reverting it inc778945806undid the state on master, but now I realize it crippled the git merge mechanism. As the merge contained a mix of commits from `master..staging-next` and other commits from `staging-next..staging`, it got the `staging-next` branch into a state that was difficult to recover. I reconstructed the "desired" state of staging-next tree by: - checking out the last commit of the problematic range:4effe769e2- `git rebase -i --preserve-merges a8a018ddc0` - dropping the mistaken merge commit and its revert from that range (while keeping reapplication from4effe769e2) - merging the last unaffected staging-next commit (803ca85c20) - fortunately no other commits have been pushed to staging-next yet - applying a diff on staging-next to get it into that state
53 lines
1.4 KiB
Nix
53 lines
1.4 KiB
Nix
{ stdenv, fetchurl
|
|
, buildPackages, bison, flex, pkg-config
|
|
, db, iptables, libelf, libmnl
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "iproute2";
|
|
version = "5.9.0";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://kernel/linux/utils/net/${pname}/${pname}-${version}.tar.xz";
|
|
sha256 = "1kys6dmhrl43iaq95n5sh02p39d7bq8i5y672qrzgwnwpjaaqpd2";
|
|
};
|
|
|
|
preConfigure = ''
|
|
# Don't try to create /var/lib/arpd:
|
|
sed -e '/ARPDDIR/d' -i Makefile
|
|
# TODO: Drop temporary version fix for 5.9 once 5.10 is out:
|
|
substituteInPlace include/version.h \
|
|
--replace "5.8.0" "${version}"
|
|
'';
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
makeFlags = [
|
|
"PREFIX=$(out)"
|
|
"SBINDIR=$(out)/sbin"
|
|
"DOCDIR=$(TMPDIR)/share/doc/${pname}" # Don't install docs
|
|
"HDRDIR=$(dev)/include/iproute2"
|
|
];
|
|
|
|
buildFlags = [
|
|
"CONFDIR=/etc/iproute2"
|
|
];
|
|
|
|
installFlags = [
|
|
"CONFDIR=$(out)/etc/iproute2"
|
|
];
|
|
|
|
depsBuildBuild = [ buildPackages.stdenv.cc ]; # netem requires $HOSTCC
|
|
nativeBuildInputs = [ bison flex pkg-config ];
|
|
buildInputs = [ db iptables libelf libmnl ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = "https://wiki.linuxfoundation.org/networking/iproute2";
|
|
description = "A collection of utilities for controlling TCP/IP networking and traffic control in Linux";
|
|
platforms = platforms.linux;
|
|
license = licenses.gpl2;
|
|
maintainers = with maintainers; [ primeos eelco fpletz globin ];
|
|
};
|
|
}
|