af8abf141d
Ports an OpenWRT patch for Atheros wireless drivers (ath*) which allows the user to change the regulatory domain code to the one which actually applies. All Atheros devices have a regulatory domain burned into their EEPROM. When using a device as AP, this domain is frequently overly restrictive when compared to the regulation which applies in the country the device actually operates in; often, this restriction disallows IR on all channels making it impossible to use the device as an AP at all. This commit introduces the NixOS config option networking.wireless.athUserRegulatoryDomain which, if enabled, applies the patch and sets the kernel config option ATH_USER_REGD. The original OpenWRT patch targets Linux 5.8.
31 lines
962 B
Nix
31 lines
962 B
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
kernelVersion = config.boot.kernelPackages.kernel.version;
|
|
linuxKernelMinVersion = "5.8";
|
|
kernelPatch = pkgs.kernelPatches.ath_regd_optional // {
|
|
extraConfig = ''
|
|
ATH_USER_REGD y
|
|
'';
|
|
};
|
|
in
|
|
{
|
|
options.networking.wireless.athUserRegulatoryDomain = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
If enabled, sets the ATH_USER_REGD kernel config switch to true to
|
|
disable the enforcement of EEPROM regulatory restrictions for ath
|
|
drivers. Requires at least Linux ${linuxKernelMinVersion}.
|
|
'';
|
|
};
|
|
|
|
config = mkIf config.networking.wireless.athUserRegulatoryDomain {
|
|
assertions = singleton {
|
|
assertion = lessThan 0 (builtins.compareVersions kernelVersion linuxKernelMinVersion);
|
|
message = "ATH_USER_REGD patch for kernels older than ${linuxKernelMinVersion} not ported yet!";
|
|
};
|
|
boot.kernelPatches = [ kernelPatch ];
|
|
};
|
|
}
|