264a83c707
(cherry picked from commit cc06f9c0be051f7ef2e1fcbd2ce13b902acc8adc) Signed-off-by: Domen Kožar <domen@dev.si>
86 lines
2.6 KiB
Nix
86 lines
2.6 KiB
Nix
{ stdenv, fetchurl, pkgconfig, zlib, libjpeg, libpng, libtiff, pam
|
|
, dbus, acl, gmp
|
|
, libusb ? null, gnutls ? null, avahi ? null, libpaper ? null
|
|
}:
|
|
|
|
let version = "2.0.4"; in
|
|
|
|
with stdenv.lib;
|
|
stdenv.mkDerivation {
|
|
name = "cups-${version}";
|
|
|
|
passthru = { inherit version; };
|
|
|
|
src = fetchurl {
|
|
url = "https://www.cups.org/software/${version}/cups-${version}-source.tar.bz2";
|
|
sha256 = "1gaakz24k6x5nc09rmpiq0xq20j1qdjc3szag8qwmyi4ky6ydmg1";
|
|
};
|
|
|
|
buildInputs = [ pkgconfig zlib libjpeg libpng libtiff libusb gnutls avahi libpaper ]
|
|
++ optionals stdenv.isLinux [ pam dbus.libs acl ];
|
|
|
|
propagatedBuildInputs = [ gmp ];
|
|
|
|
configureFlags = [
|
|
"--localstatedir=/var"
|
|
"--sysconfdir=/etc"
|
|
"--with-systemd=\${out}/lib/systemd/system"
|
|
"--enable-raw-printing"
|
|
"--enable-threads"
|
|
] ++ optionals stdenv.isLinux [
|
|
"--enable-dbus"
|
|
"--enable-pam"
|
|
] ++ optional (libusb != null) "--enable-libusb"
|
|
++ optional (gnutls != null) "--enable-ssl"
|
|
++ optional (avahi != null) "--enable-avahi"
|
|
++ optional (libpaper != null) "--enable-libpaper";
|
|
|
|
installFlags =
|
|
[ # Don't try to write in /var at build time.
|
|
"CACHEDIR=$(TMPDIR)/dummy"
|
|
"LOGDIR=$(TMPDIR)/dummy"
|
|
"REQUESTS=$(TMPDIR)/dummy"
|
|
"STATEDIR=$(TMPDIR)/dummy"
|
|
# Idem for /etc.
|
|
"PAMDIR=$(out)/etc/pam.d"
|
|
"DBUSDIR=$(out)/etc/dbus-1"
|
|
"INITDIR=$(out)/etc/rc.d"
|
|
"XINETD=$(out)/etc/xinetd.d"
|
|
"SERVERROOT=$(out)/etc/cups"
|
|
# Idem for /usr.
|
|
"MENUDIR=$(out)/share/applications"
|
|
"ICONDIR=$(out)/share/icons"
|
|
# Work around a Makefile bug.
|
|
"CUPS_PRIMARY_SYSTEM_GROUP=root"
|
|
];
|
|
|
|
postInstall = ''
|
|
# Delete obsolete stuff that conflicts with cups-filters.
|
|
rm -rf $out/share/cups/banners $out/share/cups/data/testprint
|
|
|
|
# Rename systemd files provided by CUPS
|
|
for f in $out/lib/systemd/system/*; do
|
|
substituteInPlace "$f" \
|
|
--replace "org.cups.cupsd" "cups" \
|
|
--replace "org.cups." ""
|
|
|
|
if [[ "$f" =~ .*cupsd\..* ]]; then
|
|
mv "$f" "''${f/org\.cups\.cupsd/cups}"
|
|
else
|
|
mv "$f" "''${f/org\.cups\./}"
|
|
fi
|
|
done
|
|
'' + optionalString stdenv.isLinux ''
|
|
# Use xdg-open when on Linux
|
|
substituteInPlace $out/share/applications/cups.desktop \
|
|
--replace "Exec=htmlview" "Exec=xdg-open"
|
|
'';
|
|
|
|
meta = {
|
|
homepage = https://cups.org/;
|
|
description = "A standards-based printing system for UNIX";
|
|
license = licenses.gpl2; # actually LGPL for the library and GPL for the rest
|
|
maintainers = with maintainers; [ urkud simons jgeerds ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|