45eeb24701
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/xmlsec/versions. These checks were done: - built on NixOS - /nix/store/y5z1vxy9v75bpsjl4z3xg1l4m0d8iqg1-xmlsec-1.2.26/bin/.xmlsec1-wrapped passed the binary check. - /nix/store/y5z1vxy9v75bpsjl4z3xg1l4m0d8iqg1-xmlsec-1.2.26/bin/xmlsec1 passed the binary check. - 2 of 2 passed binary check by having a zero exit code. - 0 of 2 passed binary check by having the new version present in output. - found 1.2.26 with grep in /nix/store/y5z1vxy9v75bpsjl4z3xg1l4m0d8iqg1-xmlsec-1.2.26 - directory tree listing: https://gist.github.com/35b63e4ccf9a1df1b167177e91716a4e - du listing: https://gist.github.com/d45eba60006ba229e2682ff2db682d96
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ stdenv, fetchurl, libxml2, gnutls, libxslt, pkgconfig, libgcrypt, libtool
|
|
, openssl, nss, makeWrapper }:
|
|
|
|
let
|
|
version = "1.2.26";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "xmlsec-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.aleksey.com/xmlsec/download/xmlsec1-${version}.tar.gz";
|
|
sha256 = "0l1dk344rn3j2vnj13daz72xd8j1msvzhg82n2il5ji0qz4pd0ld";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
nativeBuildInputs = [ makeWrapper pkgconfig ];
|
|
|
|
buildInputs = [ libxml2 gnutls libxslt libgcrypt libtool openssl nss ];
|
|
|
|
enableParallelBuilding = true;
|
|
doCheck = true;
|
|
|
|
# enable deprecated soap headers required by lasso
|
|
# https://dev.entrouvert.org/issues/18771
|
|
configureFlags = [ "--enable-soap" ];
|
|
|
|
# otherwise libxmlsec1-gnutls.so won't find libgcrypt.so, after #909
|
|
NIX_LDFLAGS = [ "-lgcrypt" ];
|
|
|
|
postInstall = ''
|
|
moveToOutput "bin/xmlsec1-config" "$dev"
|
|
moveToOutput "lib/xmlsec1Conf.sh" "$dev"
|
|
'';
|
|
|
|
postFixup = ''
|
|
wrapProgram "$out/bin/xmlsec1" --prefix LD_LIBRARY_PATH ":" "$out/lib"
|
|
'';
|
|
|
|
meta = {
|
|
homepage = http://www.aleksey.com/xmlsec;
|
|
downloadPage = https://www.aleksey.com/xmlsec/download.html;
|
|
description = "XML Security Library in C based on libxml2";
|
|
license = stdenv.lib.licenses.mit;
|
|
platforms = with stdenv.lib.platforms; linux ++ darwin;
|
|
updateWalker = true;
|
|
};
|
|
}
|