88 lines
3 KiB
Nix
88 lines
3 KiB
Nix
{ lib, stdenv, fetchFromGitHub, fetchpatch, cmake, kernel, installShellFiles, pkg-config
|
|
, luajit, ncurses, perl, jsoncpp, libb64, openssl, curl, jq, gcc, elfutils, tbb, protobuf, grpc
|
|
}:
|
|
|
|
with lib;
|
|
let
|
|
# Compare with https://github.com/draios/sysdig/blob/dev/cmake/modules/falcosecurity-libs.cmake
|
|
libsRev = "2160111cd088aea9ae2235d3385ecb0b1ab6623c";
|
|
libsSha256 = "sha256-TOuxXtrxujyAjzAtlX3/eCfM16mwxnmZ6Wg44SG0dTs=";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "sysdig";
|
|
version = "0.28.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "draios";
|
|
repo = "sysdig";
|
|
rev = version;
|
|
sha256 = "sha256-oE3vCmOw+gcmvGqj7Xk5injpNC/YThckJMNg5XRFhME=";
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake perl installShellFiles pkg-config ];
|
|
buildInputs = [
|
|
luajit ncurses jsoncpp libb64 openssl curl jq gcc elfutils tbb protobuf grpc
|
|
] ++ optionals (kernel != null) kernel.moduleBuildDependencies;
|
|
|
|
hardeningDisable = [ "pic" ];
|
|
|
|
postUnpack = ''
|
|
cp -r ${fetchFromGitHub {
|
|
owner = "falcosecurity";
|
|
repo = "libs";
|
|
rev = libsRev;
|
|
sha256 = libsSha256;
|
|
}} libs
|
|
chmod -R +w libs
|
|
cmakeFlagsArray+=("-DFALCOSECURITY_LIBS_SOURCE_DIR=$(pwd)/libs")
|
|
'';
|
|
|
|
cmakeFlags = [
|
|
"-DUSE_BUNDLED_DEPS=OFF"
|
|
"-DSYSDIG_VERSION=${version}"
|
|
"-DCREATE_TEST_TARGETS=OFF"
|
|
] ++ optional (kernel == null) "-DBUILD_DRIVER=OFF";
|
|
|
|
# needed since luajit-2.1.0-beta3
|
|
NIX_CFLAGS_COMPILE = "-DluaL_reg=luaL_Reg -DluaL_getn(L,i)=((int)lua_objlen(L,i))";
|
|
|
|
preConfigure = ''
|
|
cmakeFlagsArray+=(-DCMAKE_EXE_LINKER_FLAGS="-ltbb -lcurl -labsl_synchronization")
|
|
'' + optionalString (kernel != null) ''
|
|
export INSTALL_MOD_PATH="$out"
|
|
export KERNELDIR="${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
|
|
'';
|
|
|
|
postInstall =
|
|
''
|
|
# Fix the bash completion location
|
|
installShellCompletion --bash $out/etc/bash_completion.d/sysdig
|
|
rm $out/etc/bash_completion.d/sysdig
|
|
rmdir $out/etc/bash_completion.d
|
|
rmdir $out/etc
|
|
''
|
|
+ optionalString (kernel != null) ''
|
|
make install_driver
|
|
kernel_dev=${kernel.dev}
|
|
kernel_dev=''${kernel_dev#/nix/store/}
|
|
kernel_dev=''${kernel_dev%%-linux*dev*}
|
|
if test -f "$out/lib/modules/${kernel.modDirVersion}/extra/scap.ko"; then
|
|
sed -i "s#$kernel_dev#................................#g" $out/lib/modules/${kernel.modDirVersion}/extra/scap.ko
|
|
else
|
|
xz -d $out/lib/modules/${kernel.modDirVersion}/extra/scap.ko.xz
|
|
sed -i "s#$kernel_dev#................................#g" $out/lib/modules/${kernel.modDirVersion}/extra/scap.ko
|
|
xz $out/lib/modules/${kernel.modDirVersion}/extra/scap.ko
|
|
fi
|
|
'';
|
|
|
|
|
|
meta = {
|
|
description = "A tracepoint-based system tracing tool for Linux (with clients for other OSes)";
|
|
license = with licenses; [ asl20 gpl2 mit ];
|
|
maintainers = [maintainers.raskin];
|
|
platforms = ["x86_64-linux"] ++ platforms.darwin;
|
|
broken = kernel != null && versionOlder kernel.version "4.14";
|
|
homepage = "https://sysdig.com/opensource/";
|
|
downloadPage = "https://github.com/draios/sysdig/releases";
|
|
};
|
|
}
|