85f96822a0
Rust 1.50.0 incorporated a Cargo change (rust-lang/cargo#8937) in which cargo vendor erroneously changed permissions of vendored crates. This was fixed in Rust 1.51.0 (rust-lang/cargo#9131). Unfortunately, this means that all cargoSha256/cargoHashes produced during the Rust 1.50.0 cycle are potentially broken. This change updates cargoSha256/cargoHash tree-wide. Fixes #121994.
41 lines
1.1 KiB
Nix
41 lines
1.1 KiB
Nix
{ lib, stdenv, fetchCrate, rustPlatform }:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "skim";
|
|
version = "0.9.4";
|
|
|
|
src = fetchCrate {
|
|
inherit pname version;
|
|
sha256 = "0yvjzmz2vqc63l8911jflqf5aww7wxsav2yal5wg9ci9hzq6dl7j";
|
|
};
|
|
|
|
outputs = [ "out" "vim" ];
|
|
|
|
cargoSha256 = "1jk2vcm2z6r1xd6md98jzpcy7kdwp5p2fzxvvaz9qscyfnx28x17";
|
|
|
|
postPatch = ''
|
|
sed -i -e "s|expand('<sfile>:h:h')|'$out'|" plugin/skim.vim
|
|
'';
|
|
|
|
postInstall = ''
|
|
install -D -m 555 bin/sk-tmux -t $out/bin
|
|
install -D -m 644 man/man1/* -t $out/man/man1
|
|
install -D -m 444 shell/* -t $out/share/skim
|
|
install -D -m 444 plugin/skim.vim -t $vim/plugin
|
|
|
|
cat <<SCRIPT > $out/bin/sk-share
|
|
#! ${stdenv.shell}
|
|
# Run this script to find the skim shared folder where all the shell
|
|
# integration scripts are living.
|
|
echo $out/share/skim
|
|
SCRIPT
|
|
chmod +x $out/bin/sk-share
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Command-line fuzzy finder written in Rust";
|
|
homepage = "https://github.com/lotabout/skim";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ dywedir ];
|
|
};
|
|
}
|