372422390f
Bumps `matrix-synapse` to version 1.4.0[1]. With this version the following changes in the matrix-synapse module were needed: * Removed `trusted_third_party_id_servers`: option is marked as deprecated and ignored by matrix-synapse[2]. * Added `account_threepid_delegates` options as replacement for 3rdparty server features[3]. * Added `redaction_retention_period` option to configure how long redacted options should be kept in the database. * Added `ma27` as maintainer for `matrix-synapse`. Co-Authored-By: Notkea <pacien@users.noreply.github.com> Co-authored-by: Maximilian Bosch <maximilian@mbosch.me> [1] https://matrix.org/blog/2019/10/03/synapse-1-4-0-released [2] https://github.com/matrix-org/synapse/pull/5875 [3] https://github.com/matrix-org/synapse/pull/5876
88 lines
1.8 KiB
Nix
88 lines
1.8 KiB
Nix
{ lib, stdenv, python3, openssl
|
|
, enableSystemd ? stdenv.isLinux
|
|
}:
|
|
|
|
with python3.pkgs;
|
|
|
|
let
|
|
matrix-synapse-ldap3 = buildPythonPackage rec {
|
|
pname = "matrix-synapse-ldap3";
|
|
version = "0.1.3";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "0a0d1y9yi0abdkv6chbmxr3vk36gynnqzrjhbg26q4zg06lh9kgn";
|
|
};
|
|
|
|
propagatedBuildInputs = [ service-identity ldap3 twisted ];
|
|
|
|
# ldaptor is not ready for py3 yet
|
|
doCheck = !isPy3k;
|
|
checkInputs = [ ldaptor mock ];
|
|
};
|
|
|
|
in buildPythonApplication rec {
|
|
pname = "matrix-synapse";
|
|
version = "1.4.0";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "1y8yhzsf2lk2d7v4l61rpy4918c0qz276j79q88l9yazb6gw5pkk";
|
|
};
|
|
|
|
patches = [
|
|
# adds an entry point for the service
|
|
./homeserver-script.patch
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
setuptools
|
|
bcrypt
|
|
bleach
|
|
canonicaljson
|
|
daemonize
|
|
frozendict
|
|
jinja2
|
|
jsonschema
|
|
lxml
|
|
matrix-synapse-ldap3
|
|
msgpack
|
|
netaddr
|
|
phonenumbers
|
|
pillow
|
|
(prometheus_client.overrideAttrs (x: {
|
|
src = fetchPypi {
|
|
pname = "prometheus_client";
|
|
version = "0.3.1";
|
|
sha256 = "093yhvz7lxl7irnmsfdnf2030lkj4gsfkg6pcmy4yr1ijk029g0p";
|
|
};
|
|
}))
|
|
psutil
|
|
psycopg2
|
|
pyasn1
|
|
pymacaroons
|
|
pynacl
|
|
pyopenssl
|
|
pysaml2
|
|
pyyaml
|
|
requests
|
|
signedjson
|
|
sortedcontainers
|
|
treq
|
|
twisted
|
|
unpaddedbase64
|
|
] ++ lib.optional enableSystemd systemd;
|
|
|
|
checkInputs = [ mock parameterized openssl ];
|
|
|
|
checkPhase = ''
|
|
PYTHONPATH=".:$PYTHONPATH" ${python3.interpreter} -m twisted.trial tests
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://matrix.org;
|
|
description = "Matrix reference homeserver";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ ralith roblabla ekleog pacien ma27 ];
|
|
};
|
|
}
|