0a21d06682
Starting `wdisplays` on a NixOS 20.09 with `sway-1.5` breaks with the following output: ``` (wdisplays:28400): Gtk-WARNING **: 10:26:38.619: Could not load a pixbuf from /org/gtk/libgtk/theme/Adwaita/assets/bullet-symbolic.svg. This may indicate that pixbuf loaders or the mime database could not be found. Gdk-Message: 10:26:38.752: Error reading events from display: Success ``` The first two warnings can be fixed by adding `wrapGAppsHook`. The last error is an upstream bug that can be fixed by applying the patch from a pending PR[1]. [1] https://github.com/cyclopsian/wdisplays/pull/20
36 lines
1.1 KiB
Nix
36 lines
1.1 KiB
Nix
{ stdenv, fetchFromGitHub, meson, ninja, pkgconfig, gtk3, epoxy, wayland, wrapGAppsHook
|
|
, fetchpatch
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "wdisplays";
|
|
version = "1.0";
|
|
|
|
nativeBuildInputs = [ meson ninja pkgconfig wrapGAppsHook ];
|
|
|
|
buildInputs = [ gtk3 epoxy wayland ];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "cyclopsian";
|
|
repo = "wdisplays";
|
|
rev = version;
|
|
sha256 = "1xhgrcihja2i7yg54ghbwr1v6kf8jnsfcp364yb97vkxskc4y21y";
|
|
};
|
|
|
|
patches = [
|
|
# Fixes `Gdk-Message: 10:26:38.752: Error reading events from display: Success`
|
|
# https://github.com/cyclopsian/wdisplays/pull/20
|
|
(fetchpatch {
|
|
url = "https://github.com/cyclopsian/wdisplays/commit/5198a9c94b40ff157c284df413be5402f1b75118.patch";
|
|
sha256 = "1xwphyn0ksf8isy9dz3mfdhmsz4jv02870qz5615zs7aqqfcwn85";
|
|
})
|
|
];
|
|
|
|
meta = let inherit (stdenv) lib; in {
|
|
description = "A graphical application for configuring displays in Wayland compositors";
|
|
homepage = "https://github.com/cyclopsian/wdisplays";
|
|
maintainers = with lib.maintainers; [ lheckemann ma27 ];
|
|
license = lib.licenses.mit;
|
|
platforms = lib.platforms.linux;
|
|
};
|
|
}
|