c2b898da76
Passing `-l$NIX_BUILD_CORES` improperly limits the overall system load. For a build machine which is configured to run `$B` builds where each build gets `total cores / B` cores (`$C`), passing `-l $C` to make will improperly limit the load to `$C` instead of `$B * $C`. This effect becomes quite pronounced on machines with 80 cores, with 40 simultaneous builds and a cores limit of 2. On a machine with this configuration, Nix will run 40 builds and make will limit the overall system load to approximately 2. A build machine with this many cores can happily run with a load approaching 80. A non-solution is to oversubscribe the machine, by picking a larger `$C`. However, there is no way to divide the number of cores in a way which fairly subdivides the available cores when `$B` is greater than 1. There has been exploration of passing a jobserver in to the sandbox, or sharing a jobserver between all the builds. This is one option, but relatively complicated and only supports make. Lots of other software uses its own implementation of `-j` and doesn't support either `-l` or the Make jobserver. For the case of an interactive user machine, the user should limit overall system load using `$B`, `$C`, and optionally systemd's cpu/network/io limiting features. Making this change should significantly improve the utilization of our build farm, and improve the throughput of Hydra.
63 lines
2 KiB
Nix
63 lines
2 KiB
Nix
{ lib, stdenv, fetchgit, pkg-config, asciidoc, xmlto, docbook_xsl, docbook_xml_dtd_45, libxslt, libtraceevent, libtracefs, zstd, sourceHighlight }:
|
|
stdenv.mkDerivation rec {
|
|
pname = "trace-cmd";
|
|
version = "3.1.2";
|
|
|
|
src = fetchgit {
|
|
url = "git://git.kernel.org/pub/scm/utils/trace-cmd/trace-cmd.git/";
|
|
rev = "trace-cmd-v${version}";
|
|
sha256 = "sha256-wxrMEE7ZgMHM59Rv6Gk3f0zdpULuXLnY0UY797YF1a0=";
|
|
};
|
|
|
|
# Don't build and install html documentation
|
|
postPatch = ''
|
|
sed -i -e '/^all:/ s/html//' -e '/^install:/ s/install-html//' \
|
|
Documentation{,/trace-cmd,/libtracecmd}/Makefile
|
|
'';
|
|
|
|
nativeBuildInputs = [ asciidoc libxslt pkg-config xmlto docbook_xsl docbook_xml_dtd_45 sourceHighlight ];
|
|
|
|
buildInputs = [ libtraceevent libtracefs zstd ];
|
|
|
|
outputs = [ "out" "lib" "dev" "man" ];
|
|
|
|
MANPAGE_DOCBOOK_XSL="${docbook_xsl}/xml/xsl/docbook/manpages/docbook.xsl";
|
|
|
|
dontConfigure = true;
|
|
|
|
enableParallelBuilding = true;
|
|
makeFlags = [
|
|
# The following values appear in the generated .pc file
|
|
"prefix=${placeholder "lib"}"
|
|
];
|
|
|
|
# We do not mention targets (like "doc") explicitly in makeFlags
|
|
# because the Makefile would not print warnings about too old
|
|
# libraries (see "warning:" in the Makefile)
|
|
postBuild = ''
|
|
make libs doc -j$NIX_BUILD_CORES
|
|
'';
|
|
|
|
installTargets = [
|
|
"install_cmd"
|
|
"install_libs"
|
|
"install_doc"
|
|
];
|
|
installFlags = [
|
|
"LDCONFIG=false"
|
|
"bindir=${placeholder "out"}/bin"
|
|
"mandir=${placeholder "man"}/share/man"
|
|
"libdir=${placeholder "lib"}/lib"
|
|
"pkgconfig_dir=${placeholder "dev"}/lib/pkgconfig"
|
|
"includedir=${placeholder "dev"}/include"
|
|
"BASH_COMPLETE_DIR=${placeholder "out"}/share/bash-completion/completions"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "User-space tools for the Linux kernel ftrace subsystem";
|
|
homepage = "https://www.trace-cmd.org/";
|
|
license = with licenses; [ lgpl21Only gpl2Only ];
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ thoughtpolice basvandijk ];
|
|
};
|
|
}
|