80 lines
2.1 KiB
Nix
80 lines
2.1 KiB
Nix
{ stdenv, fetchurl, zlib, openssl, perl, libedit, pkgconfig, pam
|
|
, etcDir ? null
|
|
, hpnSupport ? false
|
|
, withKerberos ? false
|
|
, kerberos
|
|
}:
|
|
|
|
assert withKerberos -> kerberos != null;
|
|
|
|
let
|
|
|
|
hpnSrc = fetchurl {
|
|
url = mirror://sourceforge/hpnssh/openssh-6.6p1-hpnssh14v5.diff.gz;
|
|
sha256 = "682b4a6880d224ee0b7447241b684330b731018585f1ba519f46660c10d63950";
|
|
};
|
|
optionalString = stdenv.lib.optionalString;
|
|
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "openssh-6.7p1";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://openbsd/OpenSSH/portable/${name}.tar.gz";
|
|
sha256 = "01smf9pvn2sk5qs80gkmc9acj07ckawi1b3xxyysp3c5mr73ky5j";
|
|
};
|
|
|
|
prePatch = stdenv.lib.optionalString hpnSupport
|
|
''
|
|
gunzip -c ${hpnSrc} | patch -p1
|
|
export NIX_LDFLAGS="$NIX_LDFLAGS -lgcc_s"
|
|
'';
|
|
|
|
patches = [ ./locale_archive.patch ];
|
|
|
|
buildInputs = [ zlib openssl libedit pkgconfig pam ]
|
|
++ stdenv.lib.optional withKerberos [ kerberos ];
|
|
|
|
# I set --disable-strip because later we strip anyway. And it fails to strip
|
|
# properly when cross building.
|
|
configureFlags =
|
|
''
|
|
--with-mantype=man
|
|
--with-libedit=yes
|
|
--disable-strip
|
|
${if pam != null then "--with-pam" else "--without-pam"}
|
|
${optionalString (etcDir != null) "--sysconfdir=${etcDir}"}
|
|
${optionalString withKerberos "--with-kerberos5=${kerberos}"}
|
|
'';
|
|
|
|
preConfigure =
|
|
''
|
|
configureFlags="$configureFlags --with-privsep-path=$out/empty"
|
|
mkdir -p $out/empty
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
postInstall =
|
|
''
|
|
# Install ssh-copy-id, it's very useful.
|
|
cp contrib/ssh-copy-id $out/bin/
|
|
chmod +x $out/bin/ssh-copy-id
|
|
cp contrib/ssh-copy-id.1 $out/share/man/man1/
|
|
|
|
mkdir -p $out/etc/ssh
|
|
cp moduli $out/etc/ssh/
|
|
'';
|
|
|
|
installTargets = "install-nosysconf";
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = "http://www.openssh.org/";
|
|
description = "An implementation of the SSH protocol";
|
|
license = stdenv.lib.licenses.bsd2;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ eelco ];
|
|
broken = hpnSupport; # probably after 6.7 update
|
|
};
|
|
}
|