7aae279ad9
a67950f20b added `url` attribute
from `fetchurl` and therefore also from `fetchzip`.
We previously relied on `url` from fetchgit-based fetchers
to find the repo URL but now it will just return tarballs
in the case of `fetchFrom{GitHub,GitLab}`.
Let’s add an attribute to `fetch{git,FromGitHub,FromGitLab}`
to expose a repo URL consistently.
62 lines
2.2 KiB
Nix
62 lines
2.2 KiB
Nix
{ lib, fetchgit, fetchzip }:
|
|
|
|
{ owner, repo, rev, name ? "source"
|
|
, fetchSubmodules ? false, leaveDotGit ? null
|
|
, deepClone ? false, private ? false, forceFetchGit ? false
|
|
, sparseCheckout ? ""
|
|
, githubBase ? "github.com", varPrefix ? null
|
|
, meta ? { }
|
|
, ... # For hash agility
|
|
}@args:
|
|
|
|
let
|
|
|
|
position = (if args.meta.description or null != null
|
|
then builtins.unsafeGetAttrPos "description" args.meta
|
|
else builtins.unsafeGetAttrPos "rev" args
|
|
);
|
|
baseUrl = "https://${githubBase}/${owner}/${repo}";
|
|
newMeta = meta // {
|
|
homepage = meta.homepage or baseUrl;
|
|
|
|
# to indicate where derivation originates, similar to make-derivation.nix's mkDerivation
|
|
position = "${position.file}:${toString position.line}";
|
|
};
|
|
passthruAttrs = removeAttrs args [ "owner" "repo" "rev" "fetchSubmodules" "forceFetchGit" "private" "githubBase" "varPrefix" ];
|
|
varBase = "NIX${if varPrefix == null then "" else "_${varPrefix}"}_GITHUB_PRIVATE_";
|
|
useFetchGit = fetchSubmodules || (leaveDotGit == true) || deepClone || forceFetchGit || (sparseCheckout != "");
|
|
# We prefer fetchzip in cases we don't need submodules as the hash
|
|
# is more stable in that case.
|
|
fetcher = if useFetchGit then fetchgit else fetchzip;
|
|
privateAttrs = lib.optionalAttrs private {
|
|
netrcPhase = ''
|
|
if [ -z "''$${varBase}USERNAME" -o -z "''$${varBase}PASSWORD" ]; then
|
|
echo "Error: Private fetchFromGitHub requires the nix building process (nix-daemon in multi user mode) to have the ${varBase}USERNAME and ${varBase}PASSWORD env vars set." >&2
|
|
exit 1
|
|
fi
|
|
cat > netrc <<EOF
|
|
machine ${githubBase}
|
|
login ''$${varBase}USERNAME
|
|
password ''$${varBase}PASSWORD
|
|
EOF
|
|
'';
|
|
netrcImpureEnvVars = [ "${varBase}USERNAME" "${varBase}PASSWORD" ];
|
|
};
|
|
|
|
gitRepoUrl = "${baseUrl}.git";
|
|
|
|
fetcherArgs = (if useFetchGit
|
|
then {
|
|
inherit rev deepClone fetchSubmodules sparseCheckout; url = gitRepoUrl;
|
|
} // lib.optionalAttrs (leaveDotGit != null) { inherit leaveDotGit; }
|
|
else {
|
|
url = "${baseUrl}/archive/${rev}.tar.gz";
|
|
|
|
passthru = {
|
|
inherit gitRepoUrl;
|
|
};
|
|
}
|
|
) // privateAttrs // passthruAttrs // { inherit name; };
|
|
in
|
|
|
|
fetcher fetcherArgs // { meta = newMeta; inherit rev; }
|