4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
79 lines
2.4 KiB
Nix
79 lines
2.4 KiB
Nix
{ lib, stdenv, fetchurl, wrapQtAppsHook
|
|
, freeglut, freealut, libGLU, libGL, libICE, libjpeg, openal, openscenegraph, plib
|
|
, libSM, libunwind, libX11, xorgproto, libXext, libXi
|
|
, libXmu, libXt, simgear, zlib, boost, cmake, libpng, udev, fltk13, apr
|
|
, makeDesktopItem, qtbase, qtdeclarative, glew
|
|
}:
|
|
|
|
let
|
|
version = "2020.3.4";
|
|
shortVersion = builtins.substring 0 6 version;
|
|
data = stdenv.mkDerivation rec {
|
|
pname = "flightgear-data";
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/flightgear/release-${shortVersion}/FlightGear-${version}-data.tar.bz2";
|
|
sha256 = "1cqikbqvidfaynml9bhqfr9yw5ga35gpqrbz62z94a1skdijkpkg";
|
|
};
|
|
|
|
phases = [ "installPhase" ];
|
|
|
|
installPhase = ''
|
|
mkdir -p "$out/share/FlightGear"
|
|
tar xf "${src}" -C "$out/share/FlightGear/" --strip-components=1
|
|
'';
|
|
};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "flightgear";
|
|
# inheriting data for `nix-prefetch-url -A pkgs.flightgear.data.src`
|
|
inherit version data;
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/flightgear/release-${shortVersion}/${pname}-${version}.tar.bz2";
|
|
sha256 = "02d9h10p8hyn0a25csragj6pbwmrir1z8zb92023s9vi21j7bwy8";
|
|
};
|
|
|
|
# Of all the files in the source and data archives, there doesn't seem to be
|
|
# a decent icon :-)
|
|
iconsrc = fetchurl {
|
|
url = "http://wiki.flightgear.org/images/6/62/FlightGear_logo.png";
|
|
sha256 = "1ikz413jia55vfnmx8iwrlxvx8p16ggm81mbrj66wam3q7s2dm5p";
|
|
};
|
|
|
|
desktopItem = makeDesktopItem {
|
|
name = "flightgear";
|
|
exec = "fgfs";
|
|
icon = iconsrc;
|
|
comment = "FlightGear Flight Simulator";
|
|
desktopName = "FlightGear";
|
|
genericName = "Flight simulator";
|
|
categories = "Game;Simulation";
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake wrapQtAppsHook ];
|
|
buildInputs = [
|
|
freeglut freealut libGLU libGL libICE libjpeg openal openscenegraph plib
|
|
libSM libunwind libX11 xorgproto libXext libXi
|
|
libXmu libXt simgear zlib boost libpng udev fltk13 apr qtbase
|
|
glew qtdeclarative
|
|
];
|
|
|
|
postInstall = ''
|
|
mkdir -p "$out/share/applications/"
|
|
cp "${desktopItem}"/share/applications/* "$out/share/applications/" #*/
|
|
'';
|
|
|
|
qtWrapperArgs = [
|
|
"--set FG_ROOT ${data}/share/FlightGear"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Flight simulator";
|
|
maintainers = with maintainers; [ raskin ];
|
|
platforms = platforms.linux;
|
|
hydraPlatforms = []; # disabled from hydra because it's so big
|
|
license = licenses.gpl2;
|
|
};
|
|
}
|