45 lines
1.3 KiB
Nix
45 lines
1.3 KiB
Nix
{ stdenv, lib, fetchFromGitHub, rustPlatform, pkg-config, ncurses, openssl
|
|
, withALSA ? true, alsa-lib
|
|
, withPulseAudio ? false, libpulseaudio
|
|
, withPortAudio ? false, portaudio
|
|
, withMPRIS ? false, dbus
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "ncspot";
|
|
version = "0.10.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "hrkfdn";
|
|
repo = "ncspot";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-lZ7wFhXJ9I4IcHLLoyMTnq3MJDtUNcVdMHYLThuN7c8=";
|
|
};
|
|
|
|
cargoSha256 = "sha256-JLNB196GWpLyCrZ8fBH8+1RF1fa6PhdwFw6RW3fUARM=";
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
|
|
buildInputs = [ ncurses ]
|
|
++ lib.optional stdenv.isLinux openssl
|
|
++ lib.optional withALSA alsa-lib
|
|
++ lib.optional withPulseAudio libpulseaudio
|
|
++ lib.optional withPortAudio portaudio
|
|
++ lib.optional withMPRIS dbus;
|
|
|
|
buildNoDefaultFeatures = true;
|
|
buildFeatures = [ "cursive/pancurses-backend" ]
|
|
++ lib.optional withALSA "alsa_backend"
|
|
++ lib.optional withPulseAudio "pulseaudio_backend"
|
|
++ lib.optional withPortAudio "portaudio_backend"
|
|
++ lib.optional withMPRIS "mpris";
|
|
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
description = "Cross-platform ncurses Spotify client written in Rust, inspired by ncmpc and the likes";
|
|
homepage = "https://github.com/hrkfdn/ncspot";
|
|
license = licenses.bsd2;
|
|
maintainers = [ maintainers.marsam ];
|
|
};
|
|
}
|