73746502d8
The upstream commit tomahawk-player/tomahawk@c838959248 changed the project's README to state that the project has been abandoned, quote: This project is essentially abandoned There is noone working on it. There isn't much sense in adding any new issues in the issue tracker unless you want to fix them yourself. So I'm adding a note in the description and essentially remove my maintainership as well. Signed-off-by: aszlig <aszlig@nix.build>
55 lines
1.7 KiB
Nix
55 lines
1.7 KiB
Nix
{ stdenv, fetchurl, cmake, pkgconfig, attica, boost, gnutls, libechonest
|
|
, liblastfm, lucenepp, phonon, phonon-backend-vlc, qca2, qjson, qt4
|
|
, qtkeychain, quazip, sparsehash, taglib, websocketpp, makeWrapper
|
|
|
|
, enableXMPP ? true, libjreen ? null
|
|
, enableKDE ? false, kdelibs4 ? null
|
|
, enableTelepathy ? false, telepathy_qt ? null
|
|
}:
|
|
|
|
assert enableXMPP -> libjreen != null;
|
|
assert enableKDE -> kdelibs4 != null;
|
|
assert enableTelepathy -> telepathy_qt != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "tomahawk-${version}";
|
|
version = "0.8.4";
|
|
|
|
src = fetchurl {
|
|
url = "http://download.tomahawk-player.org/${name}.tar.bz2";
|
|
sha256 = "0j84h36wkjfjbsd7ybyji7rcc9wpjdbl0f1xdcc1g7h0nz34pc0g";
|
|
};
|
|
|
|
cmakeFlags = [
|
|
"-DLUCENEPP_INCLUDE_DIR=${lucenepp}/include"
|
|
"-DLUCENEPP_LIBRARY_DIR=${lucenepp}/lib"
|
|
];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
cmake attica boost gnutls libechonest liblastfm lucenepp phonon
|
|
qca2 qjson qt4 qtkeychain quazip sparsehash taglib websocketpp
|
|
makeWrapper
|
|
] ++ stdenv.lib.optional enableXMPP libjreen
|
|
++ stdenv.lib.optional enableKDE kdelibs4
|
|
++ stdenv.lib.optional enableTelepathy telepathy_qt;
|
|
|
|
postInstall = let
|
|
pluginPath = stdenv.lib.concatStringsSep ":" [
|
|
"${phonon-backend-vlc}/lib/kde4/plugins"
|
|
];
|
|
in ''
|
|
for i in "$out"/bin/*; do
|
|
wrapProgram "$i" --prefix QT_PLUGIN_PATH : "${pluginPath}"
|
|
done
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A multi-source music player (unmaintained)";
|
|
homepage = http://tomahawk-player.org/;
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.all;
|
|
};
|
|
}
|