0383c0aa6b
- Adds the necessary passthru vars for bundler, bundix, etc. to accept the package as a ruby. - Adds the devEnv attribute, so that jruby.devEnv can be used to get an environment with bundler and bundix installed.
62 lines
1.6 KiB
Nix
62 lines
1.6 KiB
Nix
{ stdenv, callPackage, fetchurl, makeWrapper, jre }:
|
|
|
|
let
|
|
# The version number here is whatever is reported by the RUBY_VERSION string
|
|
rubyVersion = callPackage ../ruby/ruby-version.nix {} "2" "3" "3" "";
|
|
jruby = stdenv.mkDerivation rec {
|
|
name = "jruby-${version}";
|
|
|
|
version = "9.1.12.0";
|
|
|
|
src = fetchurl {
|
|
url = "https://s3.amazonaws.com/jruby.org/downloads/${version}/jruby-bin-${version}.tar.gz";
|
|
sha256 = "15x5w4awy8h6xfkbj0p4xnb68xzfrss1rf2prk0kzk5kyjakrcnx";
|
|
};
|
|
|
|
buildInputs = [ makeWrapper ];
|
|
|
|
installPhase = ''
|
|
mkdir -pv $out/docs
|
|
mv * $out
|
|
rm $out/bin/*.{bat,dll,exe,sh}
|
|
mv $out/COPYING $out/LICENSE* $out/docs
|
|
|
|
for i in $out/bin/jruby{,.bash}; do
|
|
wrapProgram $i \
|
|
--set JAVA_HOME ${jre}
|
|
done
|
|
|
|
ln -s $out/bin/jruby $out/bin/ruby
|
|
|
|
# Bundler tries to create this directory
|
|
mkdir -pv $out/${passthru.gemPath}
|
|
mkdir -p $out/nix-support
|
|
cat > $out/nix-support/setup-hook <<EOF
|
|
addGemPath() {
|
|
addToSearchPath GEM_PATH \$1/${passthru.gemPath}
|
|
}
|
|
|
|
envHooks+=(addGemPath)
|
|
EOF
|
|
'';
|
|
|
|
passthru = rec {
|
|
rubyEngine = "jruby";
|
|
gemPath = "lib/${rubyEngine}/gems/${rubyVersion.libDir}";
|
|
libPath = "lib/${rubyEngine}/${rubyVersion.libDir}";
|
|
};
|
|
|
|
meta = {
|
|
description = "Ruby interpreter written in Java";
|
|
homepage = http://jruby.org/;
|
|
license = with stdenv.lib.licenses; [ cpl10 gpl2 lgpl21 ];
|
|
platforms = stdenv.lib.platforms.unix;
|
|
};
|
|
};
|
|
in jruby.overrideAttrs (oldAttrs: {
|
|
passthru = oldAttrs.passthru // {
|
|
devEnv = callPackage ../ruby/dev.nix {
|
|
ruby = jruby;
|
|
};
|
|
};
|
|
})
|