947c26972b
* All projects are available under NCSA license, other than dragonegg. * "Runtime" projects are dual-licensed under both NCSA and MIT: libc++, libc++abi, compiler-rt * I don't mention MIT for compiler-rt as we only build it as part of LLVM.
56 lines
1.8 KiB
Nix
56 lines
1.8 KiB
Nix
{ stdenv, fetch, cmake, libxml2, libedit, llvm, version, clang-tools-extra_src }:
|
|
|
|
let
|
|
gcc = if stdenv.cc.isGNU then stdenv.cc.cc else stdenv.cc.cc.gcc;
|
|
self = stdenv.mkDerivation {
|
|
name = "clang-${version}";
|
|
|
|
unpackPhase = ''
|
|
unpackFile ${fetch "cfe" "0x065d0w9b51xvdjxwfzjxng0gzpbx45fgiaxpap45ragi61dqjn"}
|
|
mv cfe-${version}.src clang
|
|
sourceRoot=$PWD/clang
|
|
unpackFile ${clang-tools-extra_src}
|
|
mv clang-tools-extra-* $sourceRoot/tools/extra
|
|
'';
|
|
|
|
buildInputs = [ cmake libedit libxml2 llvm ];
|
|
|
|
cmakeFlags = [
|
|
"-DCMAKE_CXX_FLAGS=-std=c++11"
|
|
] ++
|
|
# Maybe with compiler-rt this won't be needed?
|
|
(stdenv.lib.optional stdenv.isLinux "-DGCC_INSTALL_PREFIX=${gcc}") ++
|
|
(stdenv.lib.optional (stdenv.cc.libc != null) "-DC_INCLUDE_DIRS=${stdenv.cc.libc}/include");
|
|
|
|
patches = [ ./purity.patch ];
|
|
|
|
postPatch = ''
|
|
sed -i -e 's/Args.hasArg(options::OPT_nostdlibinc)/true/' lib/Driver/Tools.cpp
|
|
sed -i -e 's/DriverArgs.hasArg(options::OPT_nostdlibinc)/true/' lib/Driver/ToolChains.cpp
|
|
'';
|
|
|
|
# Clang expects to find LLVMgold in its own prefix
|
|
# Clang expects to find sanitizer libraries in its own prefix
|
|
postInstall = ''
|
|
ln -sv ${llvm}/lib/LLVMgold.so $out/lib
|
|
ln -sv ${llvm}/lib/clang/${version}/lib $out/lib/clang/${version}/
|
|
ln -sv $out/bin/clang $out/bin/cpp
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
passthru = {
|
|
lib = self; # compatibility with gcc, so that `stdenv.cc.cc.lib` works on both
|
|
isClang = true;
|
|
} // stdenv.lib.optionalAttrs stdenv.isLinux {
|
|
inherit gcc;
|
|
};
|
|
|
|
meta = {
|
|
description = "A c, c++, objective-c, and objective-c++ frontend for the llvm compiler";
|
|
homepage = http://llvm.org/;
|
|
license = stdenv.lib.licenses.ncsa;
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
};
|
|
in self
|