801078806b
By default, pkg-config output will not include Requires.private dependencies (which specify dependencies that only apply when building statically). It will only do this when passed --static. In pkgsStatic, let's ensure pkg-config is always operating in static mode, because pkgsStatic will ensure that any libraries pkg-config might find will always be static, and so will always need their Requires.private dependencies. This is very useful for Meson builds, because otherwise Meson will only pass --static to pkg-config if the dependency was explicitly "static : true", which is not likely to be the case for most stuff we're building. An alternative proposal was to patch Meson to add a special environment variable to force dependencies to be "static : true". I feel that the approach I've taken here is less invasive.
130 lines
3.3 KiB
Nix
130 lines
3.3 KiB
Nix
# The wrapper script ensures variables like PKG_CONFIG_PATH and
|
|
# PKG_CONFIG_PATH_FOR_BUILD work properly.
|
|
|
|
{ stdenvNoCC
|
|
, lib
|
|
, buildPackages
|
|
, pkg-config
|
|
, baseBinName ? "pkg-config"
|
|
, propagateDoc ? pkg-config != null && pkg-config ? man
|
|
, extraPackages ? [], extraBuildCommands ? ""
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let
|
|
stdenv = stdenvNoCC;
|
|
inherit (stdenv) hostPlatform targetPlatform;
|
|
|
|
# Prefix for binaries. Customarily ends with a dash separator.
|
|
#
|
|
# TODO(@Ericson2314) Make unconditional, or optional but always true by
|
|
# default.
|
|
targetPrefix = lib.optionalString (targetPlatform != hostPlatform)
|
|
(targetPlatform.config + "-");
|
|
|
|
# See description in cc-wrapper.
|
|
suffixSalt = replaceStrings ["-" "."] ["_" "_"] targetPlatform.config;
|
|
|
|
in
|
|
|
|
stdenv.mkDerivation {
|
|
pname = targetPrefix + pkg-config.pname + "-wrapper";
|
|
inherit (pkg-config) version;
|
|
|
|
preferLocalBuild = true;
|
|
|
|
shell = getBin stdenvNoCC.shell + stdenvNoCC.shell.shellPath or "";
|
|
|
|
inherit targetPrefix suffixSalt baseBinName;
|
|
|
|
outputs = [ "out" ] ++ optionals propagateDoc ([ "man" ] ++ optional (pkg-config ? doc) "doc");
|
|
|
|
passthru = {
|
|
inherit pkg-config;
|
|
};
|
|
|
|
dontBuild = true;
|
|
dontConfigure = true;
|
|
|
|
# Additional flags passed to pkg-config.
|
|
addFlags = lib.optional stdenv.targetPlatform.isStatic "--static";
|
|
|
|
unpackPhase = ''
|
|
src=$PWD
|
|
'';
|
|
|
|
installPhase =
|
|
''
|
|
mkdir -p $out/bin $out/nix-support
|
|
|
|
wrap() {
|
|
local dst="$1"
|
|
local wrapper="$2"
|
|
export prog="$3"
|
|
substituteAll "$wrapper" "$out/bin/$dst"
|
|
chmod +x "$out/bin/$dst"
|
|
}
|
|
|
|
echo $pkg-config > $out/nix-support/orig-pkg-config
|
|
|
|
wrap ${targetPrefix}${baseBinName} ${./pkg-config-wrapper.sh} "${getBin pkg-config}/bin/${baseBinName}"
|
|
''
|
|
# symlink in share for autoconf to find macros
|
|
|
|
# TODO(@Ericson2314): in the future just make the unwrapped pkg-config a
|
|
# propagated dep once we can rely on downstream deps comming first in
|
|
# search paths. (https://github.com/NixOS/nixpkgs/pull/31414 took a crack
|
|
# at this.)
|
|
+ ''
|
|
ln -s ${pkg-config}/share $out/share
|
|
'';
|
|
|
|
strictDeps = true;
|
|
|
|
wrapperName = "PKG_CONFIG_WRAPPER";
|
|
|
|
setupHooks = [
|
|
../setup-hooks/role.bash
|
|
./setup-hook.sh
|
|
];
|
|
|
|
postFixup =
|
|
##
|
|
## User env support
|
|
##
|
|
|
|
# Propagate the underling unwrapped pkg-config so that if you
|
|
# install the wrapper, you get anything else it might provide.
|
|
''
|
|
printWords ${pkg-config} > $out/nix-support/propagated-user-env-packages
|
|
''
|
|
|
|
##
|
|
## Man page and doc support
|
|
##
|
|
+ optionalString propagateDoc (''
|
|
ln -s ${pkg-config.man} $man
|
|
'' + optionalString (pkg-config ? doc) ''
|
|
ln -s ${pkg-config.doc} $doc
|
|
'')
|
|
|
|
+ ''
|
|
substituteAll ${./add-flags.sh} $out/nix-support/add-flags.sh
|
|
substituteAll ${../wrapper-common/utils.bash} $out/nix-support/utils.bash
|
|
''
|
|
|
|
##
|
|
## Extra custom steps
|
|
##
|
|
+ extraBuildCommands;
|
|
|
|
meta =
|
|
let pkg-config_ = if pkg-config != null then pkg-config else {}; in
|
|
(if pkg-config_ ? meta then removeAttrs pkg-config.meta ["priority"] else {}) //
|
|
{ description =
|
|
lib.attrByPath ["meta" "description"] "pkg-config" pkg-config_
|
|
+ " (wrapper script)";
|
|
priority = 10;
|
|
};
|
|
}
|