4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
59 lines
1.8 KiB
Nix
59 lines
1.8 KiB
Nix
{ stdenv, lib, fetchurl, autoreconfHook, pkgconfig, texinfo
|
|
, netcat-gnu, gnutls, gsasl, libidn2, Security
|
|
, withKeyring ? true, libsecret ? null
|
|
, systemd ? null }:
|
|
|
|
let
|
|
tester = "n"; # {x| |p|P|n|s}
|
|
journal = if stdenv.isLinux then "y" else "n";
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "msmtp";
|
|
version = "1.8.14";
|
|
|
|
src = fetchurl {
|
|
url = "https://marlam.de/${pname}/releases/${pname}-${version}.tar.xz";
|
|
sha256 = "1W8GXXEUhunCNGGFFaAqSKSNq0BRs08+EI++y2+3c7Q=";
|
|
};
|
|
|
|
patches = [
|
|
./paths.patch
|
|
];
|
|
|
|
buildInputs = [ gnutls gsasl libidn2 ]
|
|
++ stdenv.lib.optional stdenv.isDarwin Security
|
|
++ stdenv.lib.optional withKeyring libsecret;
|
|
|
|
nativeBuildInputs = [ autoreconfHook pkgconfig texinfo ];
|
|
|
|
configureFlags =
|
|
[ "--sysconfdir=/etc" ] ++ stdenv.lib.optional stdenv.isDarwin [ "--with-macosx-keyring" ];
|
|
|
|
postInstall = ''
|
|
install -d $out/share/doc/${pname}/scripts
|
|
cp -r scripts/{find_alias,msmtpqueue,msmtpq,set_sendmail} $out/share/doc/${pname}/scripts
|
|
install -Dm644 doc/*.example $out/share/doc/${pname}
|
|
|
|
substitute scripts/msmtpq/msmtpq $out/bin/msmtpq \
|
|
--replace @msmtp@ $out/bin/msmtp \
|
|
--replace @nc@ ${netcat-gnu}/bin/nc \
|
|
--replace @journal@ ${journal} \
|
|
${lib.optionalString (journal == "y") "--replace @systemdcat@ ${systemd}/bin/systemd-cat" } \
|
|
--replace @test@ ${tester}
|
|
|
|
substitute scripts/msmtpq/msmtp-queue $out/bin/msmtp-queue \
|
|
--replace @msmtpq@ $out/bin/msmtpq
|
|
|
|
ln -s msmtp $out/bin/sendmail
|
|
|
|
chmod +x $out/bin/*
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Simple and easy to use SMTP client with excellent sendmail compatibility";
|
|
homepage = "https://marlam.de/msmtp/";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ peterhoeg ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|