dc322c76d6
This only fixes CVE-2019-16866 (DoS, minor one IMHO) https://www.nlnetlabs.nl/projects/unbound/security-advisories/#vulnerability-in-parsing-notify-queries
60 lines
2 KiB
Nix
60 lines
2 KiB
Nix
{ stdenv, fetchurl, openssl, nettle, expat, libevent, dns-root-data }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "unbound";
|
|
version = "1.9.4";
|
|
|
|
src = fetchurl {
|
|
url = "https://unbound.net/downloads/${pname}-${version}.tar.gz";
|
|
sha256 = "1c2bjm13x8bkw0ds1mhn9ivd2gzmfrb0x5y76bkz09a04bxjagix";
|
|
};
|
|
|
|
# https://github.com/NLnetLabs/unbound/pull/90
|
|
postPatch = ''
|
|
substituteInPlace validator/val_secalgo.c \
|
|
--replace '&nettle_secp_256r1' 'nettle_get_secp_256r1()' \
|
|
--replace '&nettle_secp_384r1' 'nettle_get_secp_384r1()'
|
|
'';
|
|
|
|
outputs = [ "out" "lib" "man" ]; # "dev" would only split ~20 kB
|
|
|
|
buildInputs = [ openssl nettle expat libevent ];
|
|
|
|
configureFlags = [
|
|
"--with-ssl=${openssl.dev}"
|
|
"--with-libexpat=${expat.dev}"
|
|
"--with-libevent=${libevent.dev}"
|
|
"--localstatedir=/var"
|
|
"--sysconfdir=/etc"
|
|
"--sbindir=\${out}/bin"
|
|
"--with-rootkey-file=${dns-root-data}/root.key"
|
|
"--enable-pie"
|
|
"--enable-relro-now"
|
|
];
|
|
|
|
installFlags = [ "configfile=\${out}/etc/unbound/unbound.conf" ];
|
|
|
|
preFixup = stdenv.lib.optionalString (stdenv.isLinux && !stdenv.hostPlatform.isMusl) # XXX: revisit
|
|
# Build libunbound again, but only against nettle instead of openssl.
|
|
# This avoids gnutls.out -> unbound.lib -> openssl.out.
|
|
# There was some problem with this on Darwin; let's not complicate non-Linux.
|
|
''
|
|
configureFlags="$configureFlags --with-nettle=${nettle.dev} --with-libunbound-only"
|
|
configurePhase
|
|
buildPhase
|
|
installPhase
|
|
''
|
|
# get rid of runtime dependencies on $dev outputs
|
|
+ ''substituteInPlace "$lib/lib/libunbound.la" ''
|
|
+ stdenv.lib.concatMapStrings
|
|
(pkg: " --replace '-L${pkg.dev}/lib' '-L${pkg.out}/lib' --replace '-R${pkg.dev}/lib' '-R${pkg.out}/lib'")
|
|
buildInputs;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Validating, recursive, and caching DNS resolver";
|
|
license = licenses.bsd3;
|
|
homepage = https://www.unbound.net;
|
|
maintainers = with maintainers; [ ehmry fpletz globin ];
|
|
platforms = stdenv.lib.platforms.unix;
|
|
};
|
|
}
|