927b9f1728
https://github.com/casey/just/blob/master/CHANGELOG.md#0104---2021-11-21 https://github.com/casey/just/blob/master/CHANGELOG.md#0105---2021-12-4
62 lines
1.9 KiB
Nix
62 lines
1.9 KiB
Nix
{ lib, fetchFromGitHub, stdenv, rustPlatform, coreutils, bash, installShellFiles, libiconv }:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "just";
|
|
version = "0.10.5";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "casey";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "sha256-PbWV8It/ubDbZooJdt/KWihnp221Pexs0U6zMa8KSMw=";
|
|
};
|
|
cargoSha256 = "sha256-VRfk6566SNmvCxtD9EdDxDdBvQuEfjPVggXzt4VoYRg=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
buildInputs = lib.optionals stdenv.isDarwin [ libiconv ];
|
|
|
|
postInstall = ''
|
|
installManPage man/just.1
|
|
|
|
installShellCompletion --cmd just \
|
|
--bash completions/just.bash \
|
|
--fish completions/just.fish \
|
|
--zsh completions/just.zsh
|
|
'';
|
|
|
|
checkInputs = [ coreutils bash ];
|
|
|
|
preCheck = ''
|
|
# USER must not be empty
|
|
export USER=just-user
|
|
export USERNAME=just-user
|
|
export JUST_CHOOSER="${coreutils}/bin/cat"
|
|
|
|
# Prevent string.rs from being changed
|
|
cp tests/string.rs $TMPDIR/string.rs
|
|
|
|
sed -i src/justfile.rs \
|
|
-i tests/*.rs \
|
|
-e "s@/bin/echo@${coreutils}/bin/echo@g" \
|
|
-e "s@/usr/bin/env@${coreutils}/bin/env@g"
|
|
|
|
# Return unchanged string.rs
|
|
cp $TMPDIR/string.rs tests/string.rs
|
|
'';
|
|
|
|
checkFlags = [
|
|
"--skip=edit" # trying to run "vim" fails as there's no /usr/bin/env or which in the sandbox to find vim and the dependency is not easily patched
|
|
"--skip=run_shebang" # test case very rarely fails with "Text file busy"
|
|
"--skip=invoke_error_function" # wants JUST_CHOOSER to be fzf
|
|
"--skip=status_error" # "exit status" instead of "exit code"
|
|
"--skip=exit_status" # "exit status" instead of "exit code"
|
|
];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/casey/just";
|
|
changelog = "https://github.com/casey/just/blob/${version}/CHANGELOG.md";
|
|
description = "A handy way to save and run project-specific commands";
|
|
license = licenses.cc0;
|
|
maintainers = with maintainers; [ xrelkd jk ];
|
|
};
|
|
}
|