2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
63 lines
1.6 KiB
Nix
63 lines
1.6 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.salt.master;
|
|
|
|
fullConfig = lib.recursiveUpdate {
|
|
# Provide defaults for some directories to allow an immutable config dir
|
|
|
|
# Default is equivalent to /etc/salt/master.d/*.conf
|
|
default_include = "/var/lib/salt/master.d/*.conf";
|
|
# Default is in /etc/salt/pki/master
|
|
pki_dir = "/var/lib/salt/pki/master";
|
|
} cfg.configuration;
|
|
|
|
in
|
|
|
|
{
|
|
options = {
|
|
services.salt.master = {
|
|
enable = mkEnableOption "Salt master service";
|
|
configuration = mkOption {
|
|
type = types.attrs;
|
|
default = {};
|
|
description = lib.mdDoc "Salt master configuration as Nix attribute set.";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
environment = {
|
|
# Set this up in /etc/salt/master so `salt`, `salt-key`, etc. work.
|
|
# The alternatives are
|
|
# - passing --config-dir to all salt commands, not just the master unit,
|
|
# - setting a global environment variable,
|
|
etc."salt/master".source = pkgs.writeText "master" (
|
|
builtins.toJSON fullConfig
|
|
);
|
|
systemPackages = with pkgs; [ salt ];
|
|
};
|
|
systemd.services.salt-master = {
|
|
description = "Salt Master";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
path = with pkgs; [
|
|
util-linux # for dmesg
|
|
];
|
|
serviceConfig = {
|
|
ExecStart = "${pkgs.salt}/bin/salt-master";
|
|
LimitNOFILE = 16384;
|
|
Type = "notify";
|
|
NotifyAccess = "all";
|
|
};
|
|
restartTriggers = [
|
|
config.environment.etc."salt/master".source
|
|
];
|
|
};
|
|
};
|
|
|
|
meta.maintainers = with lib.maintainers; [ Flakebi ];
|
|
}
|