4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
45 lines
1.1 KiB
Nix
45 lines
1.1 KiB
Nix
{ lib, stdenv, fetchFromGitHub, gtk3, numix-icon-theme, hicolor-icon-theme }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "numix-icon-theme-square";
|
|
version = "20.09.19";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "numixproject";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "0afraarfcd66mpidmn0l90wif8kmwzdj3s09g704kwszyijxs80z";
|
|
};
|
|
|
|
nativeBuildInputs = [ gtk3 ];
|
|
|
|
propagatedBuildInputs = [ numix-icon-theme hicolor-icon-theme ];
|
|
|
|
dontDropIconThemeCache = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/share/icons
|
|
cp -a Numix-Square{,-Light} $out/share/icons
|
|
|
|
for panel in $out/share/icons/*/*/panel; do
|
|
ln -sf $(realpath ${numix-icon-theme}/share/icons/Numix/16/$(readlink $panel)) $panel
|
|
done
|
|
|
|
for theme in $out/share/icons/*; do
|
|
gtk-update-icon-cache $theme
|
|
done
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Numix icon theme (square version)";
|
|
homepage = "https://numixproject.github.io";
|
|
license = licenses.gpl3;
|
|
# darwin cannot deal with file names differing only in case
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ romildo ];
|
|
};
|
|
}
|