880e098a9f
https://github.com/matrix-org/synapse/releases/tag/1.7.2 Building for now with Python 3.7 as Python 3.8.1 changed it's behavior regarding URL parsing[1] which broke one of its dependencies[2]. [1] https://bugs.python.org/issue27657 [2] https://hydra.nixos.org/build/108652790 / https://github.com/mozilla/bleach/issues/503
93 lines
1.9 KiB
Nix
93 lines
1.9 KiB
Nix
{ lib, stdenv, python3, openssl
|
|
, enableSystemd ? stdenv.isLinux, nixosTests
|
|
}:
|
|
|
|
with python3.pkgs;
|
|
|
|
let
|
|
matrix-synapse-ldap3 = buildPythonPackage rec {
|
|
pname = "matrix-synapse-ldap3";
|
|
version = "0.1.4";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "01bms89sl16nyh9f141idsz4mnhxvjrc3gj721wxh1fhikps0djx";
|
|
};
|
|
|
|
propagatedBuildInputs = [ service-identity ldap3 twisted ];
|
|
|
|
# ldaptor is not ready for py3 yet
|
|
doCheck = !isPy3k;
|
|
checkInputs = [ ldaptor mock ];
|
|
};
|
|
|
|
in buildPythonApplication rec {
|
|
pname = "matrix-synapse";
|
|
version = "1.7.2";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "1nhzjmxzv5bvihl58cdpjw3hdghbh2pz7sg437k841mjn1qqq5lx";
|
|
};
|
|
|
|
patches = [
|
|
# adds an entry point for the service
|
|
./homeserver-script.patch
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
setuptools
|
|
bcrypt
|
|
bleach
|
|
canonicaljson
|
|
daemonize
|
|
frozendict
|
|
jinja2
|
|
jsonschema
|
|
lxml
|
|
matrix-synapse-ldap3
|
|
msgpack
|
|
netaddr
|
|
phonenumbers
|
|
pillow
|
|
(prometheus_client.overrideAttrs (x: {
|
|
src = fetchPypi {
|
|
pname = "prometheus_client";
|
|
version = "0.3.1";
|
|
sha256 = "093yhvz7lxl7irnmsfdnf2030lkj4gsfkg6pcmy4yr1ijk029g0p";
|
|
};
|
|
}))
|
|
psutil
|
|
psycopg2
|
|
pyasn1
|
|
pymacaroons
|
|
pynacl
|
|
pyopenssl
|
|
pysaml2
|
|
pyyaml
|
|
requests
|
|
signedjson
|
|
sortedcontainers
|
|
treq
|
|
twisted
|
|
unpaddedbase64
|
|
typing-extensions
|
|
] ++ lib.optional enableSystemd systemd;
|
|
|
|
checkInputs = [ mock parameterized openssl ];
|
|
|
|
doCheck = !stdenv.isDarwin;
|
|
|
|
passthru.tests = { inherit (nixosTests) matrix-synapse; };
|
|
|
|
checkPhase = ''
|
|
PYTHONPATH=".:$PYTHONPATH" ${python3.interpreter} -m twisted.trial tests
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://matrix.org;
|
|
description = "Matrix reference homeserver";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ ralith roblabla ekleog pacien ma27 ];
|
|
};
|
|
}
|