9833d56c24
Done with the help of https://github.com/Mindavi/nixpkgs-mark-broken Tool is still WIP but this is one of the first results. I manually audited the results and removed some results that were not valid. Note that some of these packages maybe should have more constrained platforms set instead of broken set, but I think not being perfectly correct is better than just keep trying to build all these things and never succeeding. Some observations: - Some darwin builds require XCode tools - aarch64-linux builds sometimes suffer from using gcc9 - gcc9 is getting older and misses some new libraries/features - Sometimes tools try to do system detection or expect some explicit settings for platforms that are not x86_64-linux
69 lines
1.5 KiB
Nix
69 lines
1.5 KiB
Nix
{ pkgs, nodejs, lib, python3Packages, fetchFromGitHub, nixosTests }:
|
|
let
|
|
nodeEnv = import ./node-env.nix {
|
|
inherit (pkgs) stdenv lib python2 runCommand writeTextFile;
|
|
inherit pkgs nodejs;
|
|
libtool = if pkgs.stdenv.isDarwin then pkgs.darwin.cctools else null;
|
|
};
|
|
nodePackages = import ./node-packages.nix {
|
|
inherit (pkgs) fetchurl nix-gitignore stdenv lib fetchgit;
|
|
inherit nodeEnv;
|
|
};
|
|
|
|
nodeDependencies = (nodePackages.shell.override (old: {
|
|
})).nodeDependencies;
|
|
in
|
|
with python3Packages; buildPythonApplication rec {
|
|
|
|
pname = "isso";
|
|
version = "0.12.6.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "posativ";
|
|
repo = pname;
|
|
rev = "refs/tags/${version}";
|
|
sha256 = "sha256-T5T3EJS8ef8uo+P9qkC+7I70qv+4PFrnhImr04Fz57U=";
|
|
};
|
|
|
|
propagatedBuildInputs = [
|
|
itsdangerous
|
|
jinja2
|
|
misaka
|
|
html5lib
|
|
werkzeug
|
|
bleach
|
|
flask-caching
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
cffi
|
|
nodejs
|
|
];
|
|
|
|
preBuild = ''
|
|
ln -s ${nodeDependencies}/lib/node_modules ./node_modules
|
|
export PATH="${nodeDependencies}/bin:$PATH"
|
|
|
|
make js
|
|
'';
|
|
|
|
checkInputs = [
|
|
pytest
|
|
pytest-cov
|
|
];
|
|
|
|
checkPhase = ''
|
|
pytest
|
|
'';
|
|
|
|
passthru.tests = { inherit (nixosTests) isso; };
|
|
|
|
meta = with lib; {
|
|
description = "A commenting server similar to Disqus";
|
|
homepage = "https://posativ.org/isso/";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ fgaz ];
|
|
# never built on aarch64-darwin since first introduction in nixpkgs
|
|
broken = stdenv.isDarwin && stdenv.isAarch64;
|
|
};
|
|
}
|