4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
51 lines
1.4 KiB
Nix
51 lines
1.4 KiB
Nix
{ lib, stdenv, fetchFromGitHub, makeWrapper
|
|
, python3, git, gnupg, less
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "git-repo";
|
|
version = "2.11.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "android";
|
|
repo = "tools_repo";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-6XsjxTYmjr/3smwwS7c+Mq1sqfgKAhWzHOY8TWlIKHU=";
|
|
};
|
|
|
|
patches = [ ./import-ssl-module.patch ];
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
buildInputs = [ python3 ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace repo --replace \
|
|
'urllib.request.urlopen(url)' \
|
|
'urllib.request.urlopen(url, context=ssl.create_default_context())'
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin
|
|
cp repo $out/bin/repo
|
|
'';
|
|
|
|
# Important runtime dependencies
|
|
postFixup = ''
|
|
wrapProgram $out/bin/repo --prefix PATH ":" \
|
|
"${stdenv.lib.makeBinPath [ git gnupg less ]}"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Android's repo management tool";
|
|
longDescription = ''
|
|
Repo is a Python script based on Git that helps manage many Git
|
|
repositories, does the uploads to revision control systems, and automates
|
|
parts of the development workflow. Repo is not meant to replace Git, only
|
|
to make it easier to work with Git.
|
|
'';
|
|
homepage = "https://android.googlesource.com/tools/repo";
|
|
license = licenses.asl20;
|
|
maintainers = [ maintainers.primeos ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|