a6d1d06a95
We are currently carrying a number of vala versions where each version is essentially just a copy of the earlier version. This PR gets rid of a ton of duplication and uses a standard builder. Secondly, we add a definition for the latest vala 0.34.1. Lastly, we add a generic "vala" that refers to the latest stable version. I have tried changing the definitions for "simple-scan" and "valum" to use the latest vala version and they at least compile OK so I'll try a massive sed job to replace all the definitions later to simply use the latest version through "vala" instead of specifying a version directly. According to upstream: "Well-maintained packages are expected to always build with the latest stable Vala version." Maybe this means that my generic builder is then no longer necessary. Oh well... I added myself to the maintainer array for vala although I have no interest in the language - this was purely a nix exercise for me but I thought it was reasonable to be the one to clean up the mess if this has side effects... Cc: @antono and @lethalman
61 lines
1.4 KiB
Nix
61 lines
1.4 KiB
Nix
{ stdenv, fetchurl, pkgconfig, flex, bison, libxslt
|
|
, glib, libiconv, libintlOrEmpty
|
|
}:
|
|
|
|
let
|
|
generic = { major, minor, sha256 }:
|
|
stdenv.mkDerivation rec {
|
|
name = "vala-${major}.${minor}";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnome/sources/vala/${major}/${name}.tar.xz";
|
|
inherit sha256;
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig flex bison libxslt ];
|
|
|
|
buildInputs = [ glib libiconv ] ++ libintlOrEmpty;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Compiler for GObject type system";
|
|
homepage = "http://live.gnome.org/Vala";
|
|
license = licenses.lgpl21Plus;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ antono lethalman peterhoeg ];
|
|
};
|
|
};
|
|
|
|
in rec {
|
|
|
|
vala_0_23 = generic {
|
|
major = "0.23";
|
|
minor = "2";
|
|
sha256 = "0g22ss9qbm3fqhx4fxhsyfmdc5g1hgdw4dz9d37f4489kl0qf8pl";
|
|
};
|
|
|
|
vala_0_26 = generic {
|
|
major = "0.26";
|
|
minor = "2";
|
|
sha256 = "1i03ds1z5hivqh4nhf3x80fg7n0zd22908w5minkpaan1i1kzw9p";
|
|
};
|
|
|
|
vala_0_28 = generic {
|
|
major = "0.28";
|
|
minor = "0";
|
|
sha256 = "0zwpzhkhfk3piya14m7p2hl2vaabahprphppfm46ci91z39kp7hd";
|
|
};
|
|
|
|
vala_0_32 = generic {
|
|
major = "0.32";
|
|
minor = "1";
|
|
sha256 = "1ab1l44abf9fj1wznzq5956431ia136rl5049cggnk5393jlf3fx";
|
|
};
|
|
|
|
vala_0_34 = generic {
|
|
major = "0.34";
|
|
minor = "1";
|
|
sha256 = "16cjybjw100qps6jg0jdyjh8hndz8a876zmxpybnf30a8vygrk7m";
|
|
};
|
|
|
|
vala = vala_0_34;
|
|
}
|