127 lines
3.7 KiB
Nix
127 lines
3.7 KiB
Nix
{ lib, stdenv, glibc, fetchurl, zlib, readline, libossp_uuid, openssl, libxml2, makeWrapper }:
|
|
|
|
let
|
|
|
|
common = { version, sha256, psqlSchema } @ args:
|
|
let atLeast = lib.versionAtLeast version; in stdenv.mkDerivation (rec {
|
|
name = "postgresql-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://postgresql/source/v${version}/${name}.tar.bz2";
|
|
inherit sha256;
|
|
};
|
|
|
|
outputs = [ "out" "lib" "doc" "man" ];
|
|
setOutputFlags = false; # $out retains configureFlags :-/
|
|
|
|
buildInputs =
|
|
[ zlib readline openssl libxml2 makeWrapper ]
|
|
++ lib.optionals (!stdenv.isDarwin) [ libossp_uuid ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
makeFlags = [ "world" ];
|
|
|
|
configureFlags = [
|
|
"--with-openssl"
|
|
"--with-libxml"
|
|
"--sysconfdir=/etc"
|
|
"--libdir=$(lib)/lib"
|
|
]
|
|
++ lib.optional (stdenv.isDarwin) "--with-uuid=e2fs"
|
|
++ lib.optional (!stdenv.isDarwin) "--with-ossp-uuid";
|
|
|
|
patches =
|
|
[ (if atLeast "9.4" then ./disable-resolve_symlinks-94.patch else ./disable-resolve_symlinks.patch)
|
|
(if atLeast "9.6" then ./less-is-more-96.patch else ./less-is-more.patch)
|
|
(if atLeast "9.6" then ./hardcode-pgxs-path-96.patch else ./hardcode-pgxs-path.patch)
|
|
./specify_pkglibdir_at_runtime.patch
|
|
];
|
|
|
|
installTargets = [ "install-world" ];
|
|
|
|
LC_ALL = "C";
|
|
|
|
postConfigure =
|
|
let path = if atLeast "9.6" then "src/common/config_info.c" else "src/bin/pg_config/pg_config.c"; in
|
|
''
|
|
# Hardcode the path to pgxs so pg_config returns the path in $out
|
|
substituteInPlace "${path}" --replace HARDCODED_PGXS_PATH $out/lib
|
|
'';
|
|
|
|
postInstall =
|
|
''
|
|
moveToOutput "lib/pgxs" "$out" # looks strange, but not deleting it
|
|
moveToOutput "lib/*.a" "$out"
|
|
moveToOutput "lib/libecpg*" "$out"
|
|
|
|
# Prevent a retained dependency on gcc-wrapper.
|
|
substituteInPlace "$out/lib/pgxs/src/Makefile.global" --replace ${stdenv.cc}/bin/ld ld
|
|
|
|
if [ -z "''${dontDisableStatic:-}" ]; then
|
|
# Remove static libraries in case dynamic are available.
|
|
for i in $out/lib/*.a; do
|
|
name="$(basename "$i")"
|
|
if [ -e "$lib/lib/''${name%.a}.so" ] || [ -e "''${i%.a}.so" ]; then
|
|
rm "$i"
|
|
fi
|
|
done
|
|
fi
|
|
'';
|
|
|
|
postFixup = lib.optionalString (!stdenv.isDarwin && stdenv.hostPlatform.libc == "glibc")
|
|
''
|
|
# initdb needs access to "locale" command from glibc.
|
|
wrapProgram $out/bin/initdb --prefix PATH ":" ${glibc.bin}/bin
|
|
'';
|
|
|
|
doInstallCheck = false; # needs a running daemon?
|
|
|
|
disallowedReferences = [ stdenv.cc ];
|
|
|
|
passthru = {
|
|
inherit readline psqlSchema;
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = https://www.postgresql.org;
|
|
description = "A powerful, open source object-relational database system";
|
|
license = licenses.postgresql;
|
|
maintainers = [ maintainers.ocharles ];
|
|
platforms = platforms.unix;
|
|
};
|
|
});
|
|
|
|
in {
|
|
|
|
postgresql93 = common {
|
|
version = "9.3.22";
|
|
psqlSchema = "9.3";
|
|
sha256 = "06p9rk2bav41ybp8ra1bpf44avw9kl5s1wyql21n5awvlm5fs60v";
|
|
};
|
|
|
|
postgresql94 = common {
|
|
version = "9.4.17";
|
|
psqlSchema = "9.4";
|
|
sha256 = "1inpkwbr2xappz3kq3jr3hsn6mwn167nijcx406q8aq56p9hqcks";
|
|
};
|
|
|
|
postgresql95 = common {
|
|
version = "9.5.12";
|
|
psqlSchema = "9.5";
|
|
sha256 = "167nlrpsnqz63gafgn21j4yc2f5g1mpfkz8qxjxk2xs6crf6zs02";
|
|
};
|
|
|
|
postgresql96 = common {
|
|
version = "9.6.8";
|
|
psqlSchema = "9.6";
|
|
sha256 = "0w7bwf19wbdd3jjbjv03cnx56qka4801srcbsayk9v792awv7zga";
|
|
};
|
|
|
|
postgresql100 = common {
|
|
version = "10.3";
|
|
psqlSchema = "10.0";
|
|
sha256 = "06lkcwsf851z49zqcws5yc77s2yrbaazf2nvbk38hpp31rw6i8kf";
|
|
};
|
|
|
|
}
|