77f7b5a3e5
This adds a NixOS module for Soft Serve, a tasty, self-hostable Git server for the command line. The module has a test that checks some basic things like creating users, creating a repo and cloning it. Co-authored-by: Sandro <sandro.jaeckel@gmail.com>
39 lines
1.1 KiB
Nix
39 lines
1.1 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, makeWrapper, nixosTests, git, bash }:
|
|
|
|
buildGoModule rec {
|
|
pname = "soft-serve";
|
|
version = "0.6.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "charmbracelet";
|
|
repo = "soft-serve";
|
|
rev = "v${version}";
|
|
hash = "sha256-gmgIuQk+8MRkuFZaJq82hHNdUMSqrylwgk6vi/Q0OQ0=";
|
|
};
|
|
|
|
vendorHash = "sha256-7lzdngj6xBpEe2nZdPW1GLbarPBdCHMnf+Dyxuq2Ikw=";
|
|
|
|
doCheck = false;
|
|
|
|
ldflags = [ "-s" "-w" "-X=main.Version=${version}" ];
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
postInstall = ''
|
|
# Soft-serve generates git-hooks at run-time.
|
|
# The scripts require git and bash inside the path.
|
|
wrapProgram $out/bin/soft \
|
|
--prefix PATH : "${lib.makeBinPath [ git bash ]}"
|
|
'';
|
|
|
|
passthru.tests = nixosTests.soft-serve;
|
|
|
|
meta = with lib; {
|
|
description = "A tasty, self-hosted Git server for the command line";
|
|
homepage = "https://github.com/charmbracelet/soft-serve";
|
|
changelog = "https://github.com/charmbracelet/soft-serve/releases/tag/v${version}";
|
|
mainProgram = "soft";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ penguwin ];
|
|
};
|
|
}
|