fda26c8476
* master: (271 commits) pysmbc: clarify license pysmbc: fix license bazel: 0.5.4 -> 0.6.0 (#29990) googler: init at 3.3 go: declare support for aarch64 firefox-beta-bin: 56.0b5 -> 57.0b4 spotify: 1.0.64.401.g9d720389-21 -> 1.0.64.407.g9bd02c2d-26 gogs: 0.11.19 -> 0.11.29 grafana: 4.5.1 -> 4.5.2 mopidy-iris: 3.4.1 -> 3.4.9 nextcloud: 12.0.2 -> 12.0.3 haskell-json-autotype: jailbreak to fix build within LTS 9.x kore: fix up kore: init at 2.0.0 glusterfs service: fix issues with useRpcbind tig: 2.2.2 -> 2.3.0 haskell-hspec-core: enable test suite again hackage-packages.nix: automatic Haskell package set update librsvg: fix thumbnailer path awscli: 1.11.108 -> 1.11.162 ...
125 lines
3.5 KiB
Nix
125 lines
3.5 KiB
Nix
{ stdenv, fetchFromGitHub, boost, cairo, fontsConf, gettext, glibmm, gtk3, gtkmm3
|
|
, libjack2, libsigcxx, libtool, libxmlxx, makeWrapper, mlt-qt5, pango, pkgconfig
|
|
, imagemagick, intltool, autoreconfHook, which, defaultIconTheme
|
|
}:
|
|
|
|
let
|
|
version = "1.0.2";
|
|
|
|
ETL = stdenv.mkDerivation rec {
|
|
name = "ETL-0.04.19";
|
|
|
|
src = fetchFromGitHub {
|
|
repo = "synfig";
|
|
owner = "synfig";
|
|
rev = version;
|
|
sha256 = "09ldkvzczqvb1yvlibd62y56dkyprxlr0w3rk38rcs7jnrhj2cqc";
|
|
};
|
|
|
|
postUnpack = "sourceRoot=\${sourceRoot}/ETL/";
|
|
|
|
nativeBuildInputs = [ autoreconfHook ];
|
|
};
|
|
|
|
synfig = stdenv.mkDerivation rec {
|
|
name = "synfig-${version}";
|
|
|
|
src = fetchFromGitHub {
|
|
repo = "synfig";
|
|
owner = "synfig";
|
|
rev = version;
|
|
sha256 = "09ldkvzczqvb1yvlibd62y56dkyprxlr0w3rk38rcs7jnrhj2cqc";
|
|
};
|
|
|
|
postUnpack = "sourceRoot=\${sourceRoot}/synfig-core/";
|
|
|
|
configureFlags = [
|
|
"--with-boost=${boost.dev}"
|
|
"--with-boost-libdir=${boost.out}/lib"
|
|
];
|
|
|
|
nativeBuildInputs = [ pkgconfig autoreconfHook gettext ];
|
|
buildInputs = [
|
|
ETL boost cairo glibmm mlt-qt5 libsigcxx libxmlxx pango
|
|
];
|
|
|
|
meta.broken = true;
|
|
};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "synfigstudio-${version}";
|
|
|
|
src = fetchFromGitHub {
|
|
repo = "synfig";
|
|
owner = "synfig";
|
|
rev = version;
|
|
sha256 = "09ldkvzczqvb1yvlibd62y56dkyprxlr0w3rk38rcs7jnrhj2cqc";
|
|
};
|
|
|
|
postUnpack = "sourceRoot=\${sourceRoot}/synfig-studio/";
|
|
|
|
postPatch = ''
|
|
for i in \
|
|
brushlib/brushlib.hpp \
|
|
gui/canvasview.cpp \
|
|
gui/compview.cpp \
|
|
gui/docks/dock_canvasspecific.cpp \
|
|
gui/docks/dock_children.cpp \
|
|
gui/docks/dock_curves.cpp \
|
|
gui/docks/dock_history.cpp \
|
|
gui/docks/dock_keyframes.cpp \
|
|
gui/docks/dock_layergroups.cpp \
|
|
gui/docks/dock_layers.cpp \
|
|
gui/docks/dock_metadata.cpp \
|
|
gui/docks/dock_params.cpp \
|
|
gui/docks/dock_timetrack.cpp \
|
|
gui/docks/dock_toolbox.cpp \
|
|
gui/docks/dockable.cpp \
|
|
gui/docks/dockdialog.cpp \
|
|
gui/docks/dockmanager.h \
|
|
gui/duck.h \
|
|
gui/duckmatic.cpp \
|
|
gui/duckmatic.h \
|
|
gui/instance.cpp \
|
|
gui/instance.h \
|
|
gui/states/state_stroke.h \
|
|
gui/states/state_zoom.cpp \
|
|
gui/widgets/widget_curves.cpp \
|
|
gui/workarea.cpp \
|
|
gui/workarearenderer/workarearenderer.h \
|
|
synfigapp/action_system.h \
|
|
synfigapp/canvasinterface.h \
|
|
synfigapp/instance.h \
|
|
synfigapp/main.h \
|
|
synfigapp/uimanager.h
|
|
do
|
|
substituteInPlace src/"$i" --replace '#include <sigc++/object.h>' '#include <sigc++/sigc++.h>'
|
|
substituteInPlace src/"$i" --replace '#include <sigc++/hide.h>' '#include <sigc++/adaptors/hide.h>'
|
|
substituteInPlace src/"$i" --replace '#include <sigc++/retype.h>' '#include <sigc++/adaptors/retype.h>'
|
|
done
|
|
'';
|
|
|
|
preConfigure = "./bootstrap.sh";
|
|
|
|
nativeBuildInputs = [ pkgconfig autoreconfHook gettext ];
|
|
buildInputs = [
|
|
ETL boost cairo glibmm gtk3 gtkmm3 imagemagick intltool
|
|
libjack2 libsigcxx libxmlxx makeWrapper mlt-qt5
|
|
synfig which defaultIconTheme
|
|
];
|
|
|
|
postInstall = ''
|
|
wrapProgram "$out/bin/synfigstudio" \
|
|
--prefix XDG_DATA_DIRS : "$XDG_ICON_DIRS:$GSETTINGS_SCHEMAS_PATH"
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A 2D animation program";
|
|
homepage = http://www.synfig.org;
|
|
license = licenses.gpl2Plus;
|
|
maintainers = [ maintainers.goibhniu ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|