2aba922d30
My idea is to provide special stdenv expressions that will contain in the path
additional cross compilers. As most expressions for programs accept a stdenv parameter,
we could substitute this parameter with the special stdenv, which will have a
generic builder that attempts the usual "--target=..." and can additionally
have an env variable like "cross" with the target architecture set.
So, finally we could have additional expressions like this:
bashRealArm = makeOverridable (import ../shells/bash) {
inherit fetchurl bison;
stdenv = stdenvCross "armv5tel-unknown-linux-gnueabi";
};
Meanwhile it does not work - I still cannot get the cross-gcc to build.
I think it does not fill the previous expressions with a lot of noise, so I
think it may be a good path to follow.
I only touched some files of the current stdenv: gcc-4.3, kernel headers
2.6.28, glibc 2.9, ...
I tried to use the gcc-cross-wrapper, that may be very outdated. Maybe I will
update it, or update the gcc-wrapper expression to make it fit the cross tools,
but meanwhile I even cannot build gcc, so I have not tested the wrapper.
This new idea on cross compiling is not similar to that of the
nixpkgs/branches/cross-compilation, which mostly added bare new expressions for
anything to be cross compiled, if I understood it correctly.
I cared not to break anything of the usual stdenv in all this work.
svn path=/nixpkgs/branches/stdenv-updates/; revision=18343
51 lines
1.5 KiB
Nix
51 lines
1.5 KiB
Nix
{stdenv, fetchurl, noSysDirs, cross ? null}:
|
|
|
|
let
|
|
basename = "binutils-2.20";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = basename + stdenv.lib.optionalString (cross != null) "-${cross}";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnu/binutils/${basename}.tar.bz2";
|
|
sha256 = "1c3m789p5rwmmnck5ms4zcnc40axss3gxzivz571al1vmbq0kpz1";
|
|
};
|
|
|
|
patches = [
|
|
# Turn on --enable-new-dtags by default to make the linker set
|
|
# RUNPATH instead of RPATH on binaries. This is important because
|
|
# RUNPATH can be overriden using LD_LIBRARY_PATH at runtime.
|
|
./new-dtags.patch
|
|
];
|
|
|
|
inherit noSysDirs;
|
|
|
|
preConfigure = ''
|
|
# Clear the default library search path.
|
|
if test "$noSysDirs" = "1"; then
|
|
echo 'NATIVE_LIB_DIRS=' >> ld/configure.tgt
|
|
fi
|
|
'';
|
|
|
|
configureFlags = "--disable-werror" # needed for dietlibc build
|
|
+ stdenv.lib.optionalString (cross != null) " --target=${cross}";
|
|
|
|
meta = {
|
|
description = "GNU Binutils, tools for manipulating binaries (linker, assembler, etc.)";
|
|
|
|
longDescription = ''
|
|
The GNU Binutils are a collection of binary tools. The main
|
|
ones are `ld' (the GNU linker) and `as' (the GNU assembler).
|
|
They also include the BFD (Binary File Descriptor) library,
|
|
`gprof', `nm', `strip', etc.
|
|
'';
|
|
|
|
homepage = http://www.gnu.org/software/binutils/;
|
|
|
|
license = "GPLv3+";
|
|
|
|
/* Give binutils a lower priority than gcc-wrapper to prevent a
|
|
collision due to the ld/as wrappers/symlinks in the latter. */
|
|
priority = "10";
|
|
};
|
|
}
|