8da7bd63ca
There are a variety of additional scripts that are included with the JRuby installation that use JRuby itself. For instance the `bin/gem` had the following contents: ```bash ❯ cat /nix/store/kglkqf56ii83yl6yrgcaj5r3s9m2fzr0-jruby-9.2.13.0/bin/gem load File.join(File.dirname(__FILE__), 'jgem') ``` This is clearly wrong. Patchshebangs was not picking up the fix as part of stdenv because the patch is not a build input but the final output itself. We have to rely on substituteInPlace so that we get the correct version. ```bash ❯ cat /nix/store/k4fnrn0dcsh2wzw81217r0ywsspb468f-jruby-9.2.13.0/bin/gem ```
67 lines
1.7 KiB
Nix
67 lines
1.7 KiB
Nix
{ stdenv, callPackage, fetchurl, makeWrapper, jre }:
|
|
|
|
let
|
|
# The version number here is whatever is reported by the RUBY_VERSION string
|
|
rubyVersion = callPackage ../ruby/ruby-version.nix {} "2" "5" "7" "";
|
|
jruby = stdenv.mkDerivation rec {
|
|
pname = "jruby";
|
|
|
|
version = "9.2.13.0";
|
|
|
|
src = fetchurl {
|
|
url = "https://s3.amazonaws.com/jruby.org/downloads/${version}/jruby-bin-${version}.tar.gz";
|
|
sha256 = "0n5glz6xm3skrfihzn3g5awdxpjsqn2k8k46gv449rk2l50w5a3k";
|
|
};
|
|
|
|
buildInputs = [ makeWrapper ];
|
|
|
|
installPhase = ''
|
|
mkdir -pv $out/docs
|
|
mv * $out
|
|
rm $out/bin/*.{bat,dll,exe,sh}
|
|
mv $out/COPYING $out/LICENSE* $out/docs
|
|
|
|
for i in $out/bin/jruby{,.bash}; do
|
|
wrapProgram $i \
|
|
--set JAVA_HOME ${jre}
|
|
done
|
|
|
|
ln -s $out/bin/jruby $out/bin/ruby
|
|
|
|
# Bundler tries to create this directory
|
|
mkdir -pv $out/${passthru.gemPath}
|
|
mkdir -p $out/nix-support
|
|
cat > $out/nix-support/setup-hook <<EOF
|
|
addGemPath() {
|
|
addToSearchPath GEM_PATH \$1/${passthru.gemPath}
|
|
}
|
|
|
|
addEnvHooks "$hostOffset" addGemPath
|
|
EOF
|
|
'';
|
|
|
|
postFixup = ''
|
|
PATH=$out/bin:$PATH patchShebangs $out/bin
|
|
'';
|
|
|
|
passthru = rec {
|
|
rubyEngine = "jruby";
|
|
gemPath = "lib/${rubyEngine}/gems/${rubyVersion.libDir}";
|
|
libPath = "lib/${rubyEngine}/${rubyVersion.libDir}";
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Ruby interpreter written in Java";
|
|
homepage = "http://jruby.org/";
|
|
license = with licenses; [ cpl10 gpl2 lgpl21 ];
|
|
platforms = platforms.unix;
|
|
maintainers = [ maintainers.fzakaria ];
|
|
};
|
|
};
|
|
in jruby.overrideAttrs (oldAttrs: {
|
|
passthru = oldAttrs.passthru // {
|
|
devEnv = callPackage ../ruby/dev.nix {
|
|
ruby = jruby;
|
|
};
|
|
};
|
|
})
|