2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
102 lines
3.3 KiB
Nix
102 lines
3.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.xdg.mime;
|
|
associationOptions = with types; attrsOf (
|
|
coercedTo (either (listOf str) str) (x: concatStringsSep ";" (toList x)) str
|
|
);
|
|
in
|
|
|
|
{
|
|
meta = {
|
|
maintainers = teams.freedesktop.members ++ (with maintainers; [ figsoda ]);
|
|
};
|
|
|
|
options = {
|
|
xdg.mime.enable = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = lib.mdDoc ''
|
|
Whether to install files to support the
|
|
[XDG Shared MIME-info specification](https://specifications.freedesktop.org/shared-mime-info-spec/shared-mime-info-spec-latest.html) and the
|
|
[XDG MIME Applications specification](https://specifications.freedesktop.org/mime-apps-spec/mime-apps-spec-latest.html).
|
|
'';
|
|
};
|
|
|
|
xdg.mime.addedAssociations = mkOption {
|
|
type = associationOptions;
|
|
default = {};
|
|
example = {
|
|
"application/pdf" = "firefox.desktop";
|
|
"text/xml" = [ "nvim.desktop" "codium.desktop" ];
|
|
};
|
|
description = lib.mdDoc ''
|
|
Adds associations between mimetypes and applications. See the
|
|
[
|
|
specifications](https://specifications.freedesktop.org/mime-apps-spec/mime-apps-spec-latest.html#associations) for more information.
|
|
'';
|
|
};
|
|
|
|
xdg.mime.defaultApplications = mkOption {
|
|
type = associationOptions;
|
|
default = {};
|
|
example = {
|
|
"application/pdf" = "firefox.desktop";
|
|
"image/png" = [ "sxiv.desktop" "gimp.desktop" ];
|
|
};
|
|
description = lib.mdDoc ''
|
|
Sets the default applications for given mimetypes. See the
|
|
[
|
|
specifications](https://specifications.freedesktop.org/mime-apps-spec/mime-apps-spec-latest.html#default) for more information.
|
|
'';
|
|
};
|
|
|
|
xdg.mime.removedAssociations = mkOption {
|
|
type = associationOptions;
|
|
default = {};
|
|
example = {
|
|
"audio/mp3" = [ "mpv.desktop" "umpv.desktop" ];
|
|
"inode/directory" = "codium.desktop";
|
|
};
|
|
description = lib.mdDoc ''
|
|
Removes associations between mimetypes and applications. See the
|
|
[
|
|
specifications](https://specifications.freedesktop.org/mime-apps-spec/mime-apps-spec-latest.html#associations) for more information.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
environment.etc."xdg/mimeapps.list" = mkIf (
|
|
cfg.addedAssociations != {}
|
|
|| cfg.defaultApplications != {}
|
|
|| cfg.removedAssociations != {}
|
|
) {
|
|
text = generators.toINI { } {
|
|
"Added Associations" = cfg.addedAssociations;
|
|
"Default Applications" = cfg.defaultApplications;
|
|
"Removed Associations" = cfg.removedAssociations;
|
|
};
|
|
};
|
|
|
|
environment.pathsToLink = [ "/share/mime" ];
|
|
|
|
environment.systemPackages = [
|
|
# this package also installs some useful data, as well as its utilities
|
|
pkgs.shared-mime-info
|
|
];
|
|
|
|
environment.extraSetup = ''
|
|
if [ -w $out/share/mime ] && [ -d $out/share/mime/packages ]; then
|
|
XDG_DATA_DIRS=$out/share PKGSYSTEM_ENABLE_FSYNC=0 ${pkgs.buildPackages.shared-mime-info}/bin/update-mime-database -V $out/share/mime > /dev/null
|
|
fi
|
|
|
|
if [ -w $out/share/applications ]; then
|
|
${pkgs.buildPackages.desktop-file-utils}/bin/update-desktop-database $out/share/applications
|
|
fi
|
|
'';
|
|
};
|
|
|
|
}
|