4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
39 lines
1 KiB
Nix
39 lines
1 KiB
Nix
{ lib, stdenv, python3, fetchFromGitHub }:
|
|
|
|
let
|
|
inherit (python3.pkgs) buildPythonApplication pytest mock pexpect;
|
|
repo = "lesspass";
|
|
in
|
|
buildPythonApplication rec {
|
|
pname = "lesspass-cli";
|
|
version = "9.1.9";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = repo;
|
|
repo = repo;
|
|
rev = version;
|
|
sha256 = "126zk248s9r72qk9b8j27yvb8gglw49kazwz0sd69b5kkxvhz2dh";
|
|
};
|
|
sourceRoot = "source/cli";
|
|
|
|
# some tests are designed to run against code in the source directory - adapt to run against
|
|
# *installed* code
|
|
postPatch = ''
|
|
for f in tests/test_functional.py tests/test_interaction.py ; do
|
|
substituteInPlace $f --replace "lesspass/core.py" "-m lesspass.core"
|
|
done
|
|
'';
|
|
|
|
checkInputs = [ pytest mock pexpect ];
|
|
checkPhase = ''
|
|
mv lesspass lesspass.hidden # ensure we're testing against *installed* package
|
|
pytest tests
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Stateless password manager";
|
|
homepage = "https://lesspass.com";
|
|
maintainers = with maintainers; [ jasoncarr ];
|
|
license = licenses.gpl3;
|
|
};
|
|
}
|