2e6bf42a22
There ver very many conflicts, basically all due to name -> pname+version. Fortunately, almost everything was auto-resolved by kdiff3, and for now I just fixed up a couple evaluation problems, as verified by the tarball job. There might be some fallback to these conflicts, but I believe it should be minimal. Hydra nixpkgs: ?compare=1538299
67 lines
2 KiB
Nix
67 lines
2 KiB
Nix
{ stdenv, fetchurl, autoconf, automake, libtool, bison
|
|
, libasr, libevent, zlib, libressl, db, pam, nixosTests
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "opensmtpd";
|
|
version = "6.4.2p1";
|
|
|
|
nativeBuildInputs = [ autoconf automake libtool bison ];
|
|
buildInputs = [ libasr libevent zlib libressl db pam ];
|
|
|
|
src = fetchurl {
|
|
url = "https://www.opensmtpd.org/archives/${pname}-${version}.tar.gz";
|
|
sha256 = "0pgv080ai7d98l9340jadp9wjiaqj2qvgpqhilcz0kps2mdiawbd";
|
|
};
|
|
|
|
patches = [
|
|
./proc_path.diff # TODO: upstream to OpenSMTPD, see https://github.com/NixOS/nixpkgs/issues/54045
|
|
];
|
|
|
|
# See https://github.com/OpenSMTPD/OpenSMTPD/issues/885 for the `sh bootstrap`
|
|
# requirement
|
|
postPatch = ''
|
|
substituteInPlace smtpd/parse.y \
|
|
--replace "/usr/libexec/" "$out/libexec/opensmtpd/"
|
|
substituteInPlace mk/smtpctl/Makefile.am --replace "chgrp" "true"
|
|
substituteInPlace mk/smtpctl/Makefile.am --replace "chmod 2555" "chmod 0555"
|
|
sh bootstrap
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--sysconfdir=/etc"
|
|
"--localstatedir=/var"
|
|
"--with-mantype=doc"
|
|
"--with-auth-pam"
|
|
"--without-auth-bsdauth"
|
|
"--with-path-socket=/run"
|
|
"--with-user-smtpd=smtpd"
|
|
"--with-user-queue=smtpq"
|
|
"--with-group-queue=smtpq"
|
|
"--with-path-CAfile=/etc/ssl/certs/ca-certificates.crt"
|
|
"--with-libevent=${libevent.dev}"
|
|
"--with-table-db"
|
|
];
|
|
|
|
# See https://github.com/OpenSMTPD/OpenSMTPD/pull/884
|
|
makeFlags = [ "CFLAGS=-ffunction-sections" "LDFLAGS=-Wl,--gc-sections" ];
|
|
|
|
installFlags = [
|
|
"sysconfdir=\${out}/etc"
|
|
"localstatedir=\${TMPDIR}"
|
|
];
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://www.opensmtpd.org/;
|
|
description = ''
|
|
A free implementation of the server-side SMTP protocol as defined by
|
|
RFC 5321, with some additional standard extensions
|
|
'';
|
|
license = licenses.isc;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ rickynils obadz ekleog ];
|
|
};
|
|
passthru.tests = {
|
|
basic-functionality-and-dovecot-interaction = nixosTests.opensmtpd;
|
|
};
|
|
}
|